Discussion :

[minnesota]

Coucou tout le monde

J'ai un petit souci avec la commande gnu "sed"...

Mon problème est comment faire en sorte, dans le cas d'un chainage de commandes ( ...;...;...; ), que chaque commande ou groupe de commandes travaille uniquement sur le dernier filtrage, en somme l'output tel qu'il serait affiché (ou le pattern space courant ?), et non sur le fichier d'entrée ou le premier filtrage... Mes essais avec les "buffers" de sed se sont avérés infructueux...

Je donne un petit exemple concret :

soit un fichier "txt.txt" dont voici le contenu :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 l1
 x1
 l2
 x2
 l3
 xt
 l4
 xp
 l5
 xs
 l6
 x+
 l7
 x7
 l8
 x8
 l9
 x9

que je dois transformer en :

xt xp
xs x+

ma ligne de commande sed qui fonctionne, mais dont je ne dois pas avoir plus d'une instance à la fois est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -n "/l3/,/l7/I!d;/x./!d;p" txt.txt |sed -n "N;s/\n//;p"

je souhaite qu'elle ait une forme proche de cette ligne qui évidemment ne produit pas le résultat escompté même quand j'y ai ajouté une étiquette et des accolades, et faute d'une maitrise totale sur la question :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -n "/l3/,/l7/I!d;/x./!d;N;s/\n//;p" txt.txt

Merci

[zipe31]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
$ sed -n '/l3/,/l7/{/x/p}' plop | sed 'N;s/\n//'
 xt xp
 xs x+

[minnesota]

Salut zipe31 et merci pour la réponse

Cependant, il ne faut pas que je redirige la sortie avec "|"... une seule et unique instance de sed doit tout faire... dans la mesure du possible...

Merci

[Flodelarab]

Bonjour

D'abord, ce qui attire l'oeil c'est que tu fais des doubles-négations.
Si tu mets l'option -n, pas la peine de détruire (d) mais p est nécessaire.
Si tu ne mets pas l'option -n, p est inutile mais d est nécessaire.

Ensuite, pour répondre à ta question, il faut filouter ou jongler avec le buffer, car sed ne peut pas travailler le fichier d'entrée et retravailler le fichier de sortie simultanément.

Ici, on peut mettre en mémoire les x...., puis utiliser les références arrières pour supprimer les sauts de lignes (1 sur 2):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -n '/^l3/,/^l7/{/^x/H};${g;s/\n\([^\n]*\)\n\([^\n]*\)/\n\1 \2/g;s/\n//;p}'

Et s'il n'y a pas deux lignes à regrouper ? Et bien il écrira la dernière ligne x seule.

[minnesota]

salut Flodelarab

C'est Super, ta réponse m'aide à y voir plus clair, merci beaucoup beaucoup

Pour les combinaisons -n/d je savais que c'était pas approprié, mais gnu sed me disait qu'il manque une commande et sur l'instant je voyais pas quoi mettre d'autre, car je voulais bien séparer chaque étape ( ;...;...; ).

Cependant, je ne cerne pas encore tout à fait le fonctionnement de sed, car quand j'enchaine les instructions, il semble bien travailler sur le résultat du traitement qui précède chaque nouvelle instruction. Est-ce un fonctionnement normal ou un effet de bord ? Et donc pour bien faire, est-ce qu'il faut systématiquement que j'imbrique les instructions avec des accolades ? S'il n'y avait pas eu ce problème avec la commande "N" je n'aurais rien vu.

J'ai également une autre question. Est-ce qu'on peut faire utiliser le "hold buffer" comme un "input stream" par sed au lieu que tout soit lu sur une seule ligne ?

Encore merci

[Flodelarab]

il semble bien travailler sur le résultat du traitement qui précède chaque nouvelle instruction.

Oui mais quand tu fais un N, c'est une nouvelle ligne qui arrive. Pas ce qui précède.

Est-ce un fonctionnement normal ou un effet de bord ?

C'est tout à fait normal.
Quand tu demandes une nouvelle ligne, il la prend en entrée sans lui appliquer ton script.

Est-ce qu'on peut faire utiliser le "hold buffer" comme un "input stream" par sed au lieu que tout soit lu sur une seule ligne ?

Non. Tu as un espace pour travailler et un espace pour retenir.
Mmais selon ton sed, tu peux faire une boucle. C'est pas une mauvaise idée:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
$ sed '/^x/!d;:z;N;s/\n[^x].*//;t z;s/\n/ /' monfichier
x1 x2  
xt xp  
xs x+  
x7 x8  
x9

Le saut t est conditionnel (il existe aussi inconditionnel b et l'opposé T). Il saute si la substitution a marché (Ici, suppression de la ligne inintéressante).

[disedorgue]

Bonjour,

Juste pour la bonne habitude concernant l'accolade fermante (pour un bloc de commande), il est conseillé de mettre un séparateur ";" entre la dernière commande du bloc et l'accolade fermante.
Cela ne mange pas de pain et au moins cela fonctionne sur la majorité des sed.

[minnesota]

Merci beaucoup Flodelarab, tu as été d'une grande aide
Salut disedorgue, message reçu. Merci à toi et à zipe31 pour vos interventions