Discussion :

[cjo78]

Bonjour,

J'ai enregistré une macro qui permet de filtrer sur #Valeur!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.AutoFilter Field:=20, Criteria1:="#VALEUR!"

Quand je place ce code le résultat me donne aucune valeur, alors que si je fais le filtre manuellement excel me filtre bien sur les cellules contenant #VALEUR!

Que faut-il coder en Criteria1 ?

Merci de votre aide car je bloque et je ne trouve rien sur le net

[casefayere]

Bonjour,

Quand tu codes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.AutoFilter Field:=20, Criteria1:="#VALEUR!"

As-tu une Sélection, au départ ?, prends-tu la bonne colonne, exemple, si ta plage est de R à T (T est pourtant la colonne 20), 10 lignes à filtrer, je traduis par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Range("R1:T10").AutoFilter Field:=3, Criteria1:="#VALEUR!"

dans ce cas, Field est à 3 (3ème colonne de la sélection), à voir........

[cjo78]

Bonjour,

Je suis bien dans la bonne colonne. D'ailleurs, quand je vais en manuel dans la colonne et que je fais personnalisation, dans le champs critère j'ai bien #VALEUR! Si je clique sur OK, le filtre fonctionne.

[casefayere]

J'en déduis que ta sélection commence en colonne A, plutôt que mettre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.AutoFilter

, mets directement la plage concernée et fais attention à "Field", comme je l'ai dit avant,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("A1:T10").AutoFilter Field:=20

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("B1:T10").AutoFilter Field:=19

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("C1:T10").AutoFilter Field:=18

voire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("C1:V10").AutoFilter Field:=20

Excuses-moi d'insister car je ne vois pas le problème

[Marc-L]

Bonjour,

je pense tenir le problème mais j'arrive à créer différentes erreurs dans la feuille mais pas #VALEUR !

Une formule pour créer cette erreur ? Merci …

[casefayere]

Bonjour Marc,

au hasard, dans les 2 cellules précédentes de la même ligne, mets des lettres et pour "Valeur mets une division de ces 2 cellules, tu obtiendras "#Valeur"

[cjo78]

Lorsque je lance mon code en mettant une valeur, cela fonctionne ex :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.AutoFilter Field:=20, Criteria1:="=2013"

J'obtiens bien dans ma colonne 20 toutes les cellules contenant 2013.

Je change uniquement le critère, pour avoir les cellules contenant #VALEUR!, je relance la macro et cela ne fonctionne pas, je n'ai pas les cellules contenant #VALEUR! :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selection.AutoFilter Field:=20, Criteria1:="=#VALEUR!"

Je passe sous excel, je vais dans ma colonne 20, je filtre sur #VALEUR! et cela fonctionne

Pour obtenir #VALEUR!, recherche d'un caractére qui n'existe pas dans une cellule.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=CHERCHE(".";S4;1)

[casefayere]

Méa Culpa, je n'avais pas testé, ne connaissant pas la raison, je te propose cette solution, si les autres cellules ont également des formules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Cells.SpecialCells(xlCellTypeFormulas).EntireRow.Hidden = True
Cells.SpecialCells(xlCellTypeFormulas, xlErrors).EntireRow.Hidden = False

[Marc-L]

Non, la santé mentale de cjo78 n'est pas à mettre en doute, je reproduis bien son problème dans la version 2003 !
Si d'autres peuvent tester dans les versions ultérieures car il me semble que ce soit un dysfonctionnement ponctuel,
bref un bug quoi !

Car je le reproduis aussi avec une autre erreur ne fonctionnant déjà pas en filtre manuel !

Je confirme si un filtre est déjà activé dans la feuille de calcul,
Selection.AutoFilter quelque soit la plage de cellules sélectionnée fonctionne bien …
… mais déclenchera une erreur dans le cas contraire ou si la sélection n'est pas une cellule !

Ma piste n'a rien donné mais a été quand même utile par la suite.
Une cellule en erreur correspond à un numéro d'erreur mais hélas impossible à passer dans le filtre, en tout cas en version 2003 …
L'astuce consiste alors à récupérer ce numéro d'erreur en sélectionnant une cellule en erreur dans la feuille de calcul
puis dans la fenêtre Exécution de l'environnement VBA taper ? activecell puis valider …

Mon code est peut-être bien de la bidouille mais a le mérite d'obtenir le résultat escompté !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Function SpecCells(SCV As XlSpecialCellsValue, Optional Rg As Range) As Range
    Dim Rc As Range, Rf As Range
 
    If Rg Is Nothing Then Set Rg = ActiveSheet.UsedRange
    On Error Resume Next
    Set Rc = Rg.SpecialCells(xlCellTypeConstants, SCV)
    Set Rf = Rg.SpecialCells(xlCellTypeFormulas, SCV)
 
    If Not Rc Is Nothing And Not Rf Is Nothing Then Set SpecCells = Union(Rc, Rf) _
                                               Else Set SpecCells = IIf(Rf Is Nothing, Rc, Rf)
 
    Set Rc = Nothing:  Set Rf = Nothing:  Set Rg = Nothing
End Function
 
 
Sub Demo()
    Dim Cel As Range, Rg As Range
 
    COL& = 1
    [H1:H10].AutoFilter COL, "#VALEUR!"
 
    With ActiveSheet.AutoFilter
        Select Case .Filters(COL).Criteria1
               Case "=#NOM?"
                    V = CVErr(2029)
 
               Case "=#VALEUR!"
                    V = CVErr(2015)
        End Select
 
        If IsError(V) Then
            Set Rg = SpecCells(xlErrors, .Range.Columns(COL))
 
            If Not Rg Is Nothing Then
                Application.ScreenUpdating = False
 
                For Each Cel In Rg
                    If Cel.Value = V Then Rows(Cel.Row).Hidden = False
                Next
                                    Set Rg = Nothing
                Application.ScreenUpdating = True
            End If
        End If
    End With
End Sub

Afin d'accélérer la procédure Demo, seules les cellules en erreur sont traitées.
Adapter les lignes n°19 & 20 pour la colonne du filtre et sa plage …

__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …


__________________________________________________________________________________________
Quand une femme offre son soutien, est-ce par sein-pathie ?!