Discussion :

[Le Sage]

Bonjour à toutes et tous !

Je souhaite, à partir d'Excel 2010 et en VBA, afficher dans la fenêtre actuelle d'Outlook 2010 le calendrier à une date donnée (disons pour l'exemple le 01/03/2013) et selon un affichage précis (disons, toujours pour l'exemple, Semaine de travail).

J'ai trouvé ceci :

Explorer.CurrentFolder, propriété

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub ChangeCurrentFolder()
    Dim myNamespace As Outlook.NameSpace
 
    Set myNamespace = Application.GetNamespace("MAPI")
    Set Application.ActiveExplorer.CurrentFolder = _
    myNamespace.GetDefaultFolder(olFolderCalendar)
End Sub

Je l'ai donc adapté pour Excel (puisque c'est de là que je souhaite partir) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Calendrier()
    Dim appOutlook As Outlook.Application
    Dim outEspace As Outlook.Namespace
    Dim outExplorer As Outlook.Explorer
    Dim outCalendrier As Outlook.MAPIFolder
 
    Set appOutlook = Outlook.Application
    Set outEspace = appOutlook.Session
    Set outExplorer = appOutlook.ActiveExplorer
    Set outCalendrier = outEspace.GetDefaultFolder(olFolderCalendar)
 
    outExplorer.CurrentFolder = outCalendrier
 
    Set appOutlook = Nothing
    Set outEspace = Nothing
    Set outExplorer = Nothing
    Set outCalendrier = Nothing
End Sub

En le faisant tourner j'obtiens ceci :

Erreur d'exécution '-2147024891 (80070005)':
Vous ne disposez pas des autorisations nécessaires pour effectuer cette opération.

Je n'ai trouvé sur la toile que des publications concernant l'erreur 80070005 lors de l'installation de Vista. Celle-ci semble relative à la sécurité des dossiers...
J'ai donc tenté d'autoriser l'accès au dossier Outlook et à tous les .pst qui s'ytrouve à "Tout le Monde" en accès total.

Rien n'a changé, j'ai toujours le même message d'erreur...

Merci d'avance à quiconque saura me mettre sur la voie !

Dans l'intervalle, bien cordialement,
Eric.

[parmi]

Bonjour,

Voici un exemple trouvé dans l'aide.
Ça peut te mettre sur une piste de départ...
Mais ce ne sera pas dans la fenêtre actuelle d'Outlook, mais plutôt dans une vue à part...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub TestGoToDate()
    Dim appOutlook As Outlook.Application
    Dim outEspace As Outlook.Namespace
    Dim oCV As Outlook.CalendarView
    Dim oExpl As Outlook.Explorer
    Dim datGoTo As Date
 
    Set appOutlook = Outlook.Application
    Set outEspace = appOutlook.GetNamespace("MAPI")    
 
    datGoTo = "5/7/2013"  'mm/jj/aaaa
 
    ' Display the contents of the Calendar default folder.
    Set oExpl = appOutlook.Explorers.Add( _
        appOutlook.Session.GetDefaultFolder(olFolderCalendar), olFolderDisplayFolderOnly)
    oExpl.Display
 
    ' Retrieve the current view by calling the
    ' CurrentView property of the Explorer object.
    Set oCV = oExpl.CurrentView
 
    ' Set the CalendarViewMode property of the
    ' current view to display items by day.
    oCV.CalendarViewMode = olCalendarView5DayWeek
 
    ' Call the GoToDate method to set the date
    ' for which information is displayed in the view.
    oCV.GoToDate datGoTo
End Sub

Et voici une méthode qui utilise la session ouverte d'Outlook pour sélectionner le calendrier et modifier sa date

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub TestGoToDate()
    Dim appOutlook As Outlook.Application
    Dim outEspace As Outlook.Namespace
    Dim oCV As Outlook.CalendarView
    Dim Fold As Outlook.Folder
    Dim datGoTo As Date
 
    Set appOutlook = Outlook.Application
    Set outEspace = appOutlook.GetNamespace("MAPI")
 
    datGoTo = "5/7/2013"  'mm/jj/aaaa
 
    Set Fold = outEspace.GetDefaultFolder(olFolderCalendar)
 
    ' Affiche le calendrier de la session en cours
    Set appOutlook.ActiveExplorer.CurrentFolder = Fold
 
    Set oCV = appOutlook.ActiveExplorer.CurrentView
 
    oCV.CalendarViewMode = olCalendarView5DayWeek  'calendrier type 5 jours
 
    oCV.GoToDate datGoTo  'changement de date
End Sub

[Le Sage]

Bonjour parmi, et un grand merci pour ta participation plus qu'efficace !

J'ai à peine modifié le dernier code que tu m'as fourni et j'ai publié la solution finale ICI.