Discussion :

[iliesss]

bonjour
SVP j'ai un tableau ou une plage de A2:D.....
le filtre est uniquement dans les colonnes C et D
dans la cellule B1 j’écris la valeur de filtre
comment en VBA lorsque j’écris en B1 la valeur de filtre le tableau affiche cette valeur dans la colonne C et D et si la cellule B1 est vide j’obtiens mon tableau sans filtre
merci beaucoup

[Daniel.C]

Bonjour,

Le code suivant filtre uniquement les lignes qui contiennent B1 en colonne C et D. Si tu voulais les ligne contenant B1 en C ou D, dis-le.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test1()
    With ActiveSheet
        If .[B1] = "" Then
            .AutoFiltermode=false
        Else
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AutoFilter 3, .[B1]
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AutoFilter 4, .[B1]
        End If
    End With
End Sub

Si tu veux que le filtre change automatiquement quand la valeur de B1 change, mets la macro suivante dans le module de la feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$B$1" Then Exit Sub
    With ActiveSheet
        If .[B1] = "" Then
            .AutoFilterMode = False
        Else
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AutoFilter 3, .[B1]
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AutoFilter 4, .[B1]
        End If
    End With
End Sub

[iliesss]

merci beaucoup Mr Daniel
et SVP pour le C ou D comment .

[Daniel.C]

Regarde le classeur joint; il y a 3 façons de faire :

1. feuille "Filtre auto"
Avec un filtre automatique, en ajoutant un colonne (E) avec la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(OU(C3=$B$1;D3=$B$1);1;0)

en E3, à recopier vers le bas. Le code filtre les 1 de la colonne ajoutée, dans le module feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$B$1" Then Exit Sub
    With ActiveSheet
        If .[B1] = "" Then
            .AutoFilterMode = False
        Else
            .Range(.[A2], .Cells(.Rows.Count, 5).End(xlUp)).AutoFilter 5, 1
        End If
    End With
End Sub

2. feuille "Filtre avancé 1" avec un filtre avancé. la zone de critères définie en F2:G4 signifie B1 en C ou D. Code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$B$1" Then Exit Sub
    With ActiveSheet
        If .[B1] = "" Then
            .ShowAllData
        Else
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AdvancedFilter xlFilterInPlace, .Range("F2:G4")
        End If
    End With
End Sub

3. feuille "Filtre avancé 2" également avec un filtre avancé. On définit ici un champ calculé dans la zone de critères :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=OU(C3=$B$1;D3=$B$1)

Code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address <> "$B$1" Then Exit Sub
    With ActiveSheet
        If .[B1] = "" Then
            .ShowAllData
        Else
            .Range(.[A2], .Cells(.Rows.Count, 4).End(xlUp)).AdvancedFilter xlFilterInPlace, .Range("F2:F3")
        End If
    End With
End Sub

[iliesss]

merci mon ami tu mérite 5 étoiles
merci beaucoup

[iliesss]

bonjour
SVP j'ai un tous petit problème si je ne mettre rien dans F2 et F3 le code ne fonction pas
voici mon fichier démo

[gFZT82]

Bonjour iliesss,
Bonjour Daniel,

Tu as peut-être intérêt à ne pas utiliser un filtre mais effectuer un simple masquage des lignes.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Ligne As Long, DerLigne As Long
    If Target.Address <> "$B$1" Then Exit Sub
    Application.ScreenUpdating = False
    With ActiveSheet
        DerLigne = .UsedRange.Rows.Count
        If Target = "" Then
            .Rows("3:" & DerLigne).Hidden = False
        Else
            For Ligne = DerLigne To 3 Step -1
                If .Range("C" & Ligne) = Target Or .Range("D" & Ligne) = Target Then
                    Rows(Ligne).Hidden = False
                Else
                    Rows(Ligne).Hidden = True
                End If
            Next Ligne
        End If
    End With
    Range("B1").Select
End Sub

Cordialement.