Discussion :

[vincenthird]

Bonjour à tous,

Je fais mes premiers pas sous VBA après avoir parcouru SAS et me voilà confronté à un tout nouveau langage

J'essaie de créer une macro afin de constituer une petite base de données en me servant d'un formulaire en colonne qui va transposer les données sur une autre feuille mais en ligne.

J'ai fouillé sur le net et j'ai dégoté le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub transpose_dans_tableau()
'Atteindre le formulaire et mémoriser les données
    Sheets("New").Select
    Range("E4:E20").Select
    Selection.Copy
 
'Test pour déterminer la ligne où coller les infos dans le tableau
    Sheets("DB").Select
    valeurA2 = Range("A2").Value
    If valeurA2 = "" Then
    Range("A2").Select
    Else
    Range("A1").Select
    Selection.End(xlDown).Select
    ligne_active_base = ActiveCell.Row
    Range("A" & ligne_active_base + 1).Select
    End If
 
'Mémorise le n° de la ligne où coller les données
    ligne_active_base = ActiveCell.Row
 
'Collage avec transposition
    Range("A" & ligne_active_base).Select
    Selection.PasteSpecial Paste:=xlPasteAllExceptBorders, _
    Operation:=xlNone, SkipBlanks:=False, Transpose:=True
 
'Rendre vierge le formulaire
    Sheets("New").Select
    Range("E4:E20").Select
    Selection.ClearContents
    Range("E4").Select
 
'Retourner dans le tableau
    Sheets("DB").Select
    Range("A1").Select
 
End Sub

J'obtiens une erreur '1004' j'en ai déduis (d'après les autres discussions) qu'il s'agit d'une erreur dans la transpose... Mais alors où est l'erreur ? Pour le moment le VBA reste du chinois... Mais avec votre aide je vais vite apprendre

Merci d'avance

[edelweisseric]

Bonjour à tous
Bonjour vincenthird

Si j'ai bien compris ce que tu souhaites :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub transpose_dans_tableau()
Dim P1 As Variant
'Test pour déterminer la ligne où coller les infos dans le tableau
ligne_active_base = Sheets("DB").Range("A65536").End(xlUp).Row + 1
 
P1 = Sheets("New").Range("E4:E20")
Sheets("DB").Range("a" & ligne_active_base & ":Q" & ligne_active_base) = Application.Transpose(P1)
Sheets("New").Range("E4:E20").ClearContents
End Sub

et tu lances avec un bouton sur la feuille "DB"
Eric

[vincenthird]

En fait la feuille DB sera ma base de donnée en ligne et dans la feuille New j'entre mes données en colonne avec un bouton associé à la macro pour intégrer ces dites données dans la feuille DB.

[philoul]

Personnellement je préfère utiliser Cells plutôt que Range en triturant l'adresse texte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
For i =4 to 20
     sheets("DB").Cells(ligne_active_base,i).value = sheets("New").Cells(i,5).value
     sheets("New").Cells(i,5).value = ""
Next i

Valeur 5 si données dans la colonne E

[vincenthird]

Je vais essayer Merci philoul

@edelweisseric,

Ton code marche impec' ! Et en quelques lignes seulement Merci beaucoup