Discussion :

[splog]

Bonjour,
Je voudrais combiner 2 fois la fonction rechercheV.
J'ai sur une feuille1 une liste de client que je vais voir tous les jours, à qui je facture un montant variable suivant la journée (Dimanche etc).
Sur une autre feuille2 je voudrais faire une recherche du montant payé en fonction de la date...
La fonction rechercheV ne fonctionne pas car elle trouve plusieurs occurences du même client dans la table matrice.
Donc il faudrait lui dire de rechercher la date et ensuite le nom du client et me re-sortir le chiffre....
Mais je ne vois pas trop comment l'écrire...

D'avance merci

[EngueEngue]

Sommeprod(clients=clientquetuveux*date=datequetuveux*montant)

[splog]

Soit l'ecrit mal soit ce n'est pas la bonne formule...

=SOMMEPROD('Suivi journalier'!$B$2:$B$4000=B2)*('Suivi journalier'!$A$2:$A$4000=A2)*('Suivi journalier'!$K$2:$K$4000)

En suivi journalier B:B la liste des clients
En suivi journalier A:A les dates
et enfin en suivi journalier K:K les montants a recherché...
ca ne me renvoie pas d'erreur juste pas de valeur...

[gFZT82]

Bonjour,

C'était bon, à 2 parenthèses près

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(('Suivi journalier'!$B$2:$B$4000=B2)*('Suivi journalier'!$A$2:$A$4000=A2)*('Suivi journalier'!$K$2:$K$4000))

Cordialement.

[splog]

Bonjour,

C'était bon, à 2 parenthèses près

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(('Suivi journalier'!$B$2:$B$4000=B2)*('Suivi journalier'!$A$2:$A$4000=A2)*('Suivi journalier'!$K$2:$K$4000))

Cordialement.

J'avais essayé mais cela me renvoyait #valeurs!

[Zodette]

On peux utiliser la fonction INDEX()
Premier argument = ton tableau donc $A$2:$K$4000
Deuxième argument = No de ligne dans le tableau
Troisième argument = No de colonne (comme dans RECHERCHEV)

Pour trouver le no de ligne, on utilise la fonction EQUIV() qui retourne la position d'un élément dans une liste. Dans notre cas c'est la position de 2 éléments, donc on va concaténer les éléments à trouver et les colonnes dans lesquelles on recherche.

Cela donnera la fonction suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

{=INDEX($A$2:$X$4000;EQUIV("Clientquetuveux"&"datequetuveux";$B$2:$B$4000&$A$2:$A$4000;0);"no de colonne qui doit retourner la valeur")}

La fonction doit être validée de façon matricielle, c'est à dire avec Ctrl+Maj+Entrée

Elle devrait retourner la valeur dans la colonne K si dans l'argument "no de colonne" on met 11

En suivant cette logique, on peut rechercher sur le nombre de colonnes désirées.

Cordialement

Cordialement

[gFZT82]

J'avais essayé mais cela me renvoyait #valeurs!

Moi aussi j'ai essayé
Fais une comparaison des classeurs pour trouver ce qui cloche.

Cordialement

[splog]

Est ce que cela peut venir du fait que le contenue de ma cellule montant est le résultat d'une formule?
(formule de la colonne K:K "montant"
=SI(B2>0;SI(J2="Oui";(RECHERCHEV(D2;Soins!A:B;2;FAUX)+(E2*Soins!$B$15)+(F2*Soins!$B$14))*I2;(RECHERCHEV(D2;Soins!A:B;2;FAUX)+(E2*Soins!$B$15)+(F2*Soins!$B$14))*I2*0,9);"")

Ou que les données de la colonne client viennent d'une liste déroulante?

[Philippe Tulliez]

Bonjour,
Poser la question, c'est déjà y répondre
Il est clair que si tu utilises la colonne K pour effectuer les sommes d'une colonne à l'aide de la formule SOMMEPROD il est préférable d'avoir une valeur nulle (0) plutôt qu'une chaîne vide.
Si tu as une chaîne vide dans la colonne qui sert à effectuer la somme, la formule renverra effectivement une valeur d'erreur #VALEUR!.

[splog]

Bonjour,
Poser la question, c'est déjà y répondre
Il est clair que si tu utilises la colonne K pour effectuer les sommes d'une colonne à l'aide de la formule SOMMEPROD il est préférable d'avoir une valeur nulle (0) plutôt qu'une chaîne vide.
Si tu as une chaîne vide dans la colonne qui sert à effectuer la somme, la formule renverra effectivement une valeur d'erreur #VALEUR!.

Vous entendez par chaîne vide une cellule qui serait vide dans la colonne et donc qui forcément ne reverrai pas de résultat?
Parce qu'il y a forcement un montant en face de mon client donc pas de vide dans la colonne...
Mais j'ai tenté en rentrant un montant directement sans passer par la formule et l'erreur est tjs la...

[Philippe Tulliez]

Bonjour,
Je parle de votre message #8 où vous posez la question si la formule ci-dessous ne pourrait pas poser un problème (formule qui serait placée dans les cellules de la colonne K qui elle-même est utilisée dans la formule SOMMEPROD pour avoir un total).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(B2>0;SI(J2="Oui";(RECHERCHEV(D2;Soins!A:B;2;FAUX)+(E2*Soins!$B$15)+(F2*Soins!$B$14))*I2;(RECHERCHEV(D2;Soins!A:B;2;FAUX)+(E2*Soins!$B$15)+(F2*Soins!$B$14))*I2*0,9);"")

La chaîne vide renvoyée par le troisième argument de la formule SI) est mise en rouge et devrait être remplacée par une valeur nulle soit 0.

Pour vous en convaincre, mettez 4 dates en plage A2:A6, 4 numéros en B2:B6 et 4 montants en C2:C6
Comme ci-dessous
15/02/2013 C001 20
15/02/2013 C002 10
15/02/2013 C002 10
15/02/2013 C001 10
En cellule D2 tapez cette formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD( ($B$2:$B$5="C001") * ($A$2:$A$5=DATE(2013;2;15)) * $C$2:$C$5)

La formule va renvoyer 30, ensuite en C2, tapez =0, la formule renvoie 10, ensuite tapez ="", la formule renvoie #VALEUR!.