Discussion :

[NoodleDS]

Bonjour à tous,

Je débute en programmation VBA sous Excel et je souhaiterai un peu d'aide.
J'ai créé une macro enregistrée à partir de la formule "recherchev".
Malheureusement celle-ci ne s'adapte pas à tous les cas que je peux rencontrer. En effet, le contenu de la colonne que je souhaite comparer à ma matrice peut-être d'une fois à l'autre totalement différent. Je peux avoir une fois 5 cellules avec des informations et une autre fois 10 cellules, etc.
De même, la matrice qui est également sur une colonne peut avoir un contenu d'une fois à l'autre totalement différent.
C'est pourquoi, je souhaiterai pouvoir remplacer le code générer par la macro enregistrée par un petit code VBA qui s’adapterait automatiquement au contenu de la colonne comparée et au contenu de la Matrice.

Exemple :
Ce code effectuerai la "recherchev" en colonne B - FEUIL1. Il comparait exactement la colonne A - FEUIL1 jusqu'à la dernière cellule non vide à la Matrice (colonne A - FEUIL2) jusqu'à la dernière cellule non vide.

Je vous remercie par avance pour votre aide.

Cordialement.
NoodleDS

[Daniel.C]

Bonjour,

Pas sûr d'avoir bien compris, notamment quelle colonne doit renvoyer le résultat.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim Plage As Range, C As Range
With Sheets("Feuil1")
    Set Plage = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp))
End With
With Sheets("Feuil2")
    For Each C In Plage
        C.Offset(, 1) = Application.VLookup(C.Value, .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)), 1, 0)
    Next C
End With

[NoodleDS]

Bonjour,

Je te remercie Daniel.C pour cette réponse très rapide qui fonctionne parfaitement.
Juste une petite demande supplémentaire. Est-ce qu'il serait possible de remplacer "#N/A" du retour lorsqu'il ne trouve pas l'information dans la Matrice, par un commentaire comme "Non présent".

Cordialement.
NoodleDS

[Daniel.C]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim Plage As Range, C As Range, Teste
With Sheets("Feuil1")
    Set Plage = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp))
End With
With Sheets("Feuil2")
    For Each C In Plage
        Teste = Application.VLookup(C.Value, .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)), 1, 0)
        If IsError(Teste) Then
            C.Offset(, 1) = "Non présent"
        Else
        C.Offset(, 1) = Application.VLookup(C.Value, .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)), 1, 0)
        End If
    Next C
End With

[Marc-L]

Bonjour Daniel,

je ne comprend pas pourquoi après l'affectation de la variable Teste tu refais le même calcul pour la cellule,

les lignes n°8 à 12 ne pourraient-elles pas être simplifiées en une seule :

C.Offset(, 1) = IIf(IsError(Teste), "Non présent", Teste) ,


ou bien par If IsError(Teste) Then C.Offset(, 1) = "Non présent" Else C.Offset(, 1) = Teste …


__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

[Daniel.C]

Effectivement, c'est une erreur de copier coller. Mon intention était de mettre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim Plage As Range, C As Range, Teste
With Sheets("Feuil1")
    Set Plage = .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp))
End With
With Sheets("Feuil2")
    For Each C In Plage
        Teste = Application.VLookup(C.Value, .Range(.[A1], .Cells(.Rows.Count, 1).End(xlUp)), 1, 0)
        If IsError(Teste) Then
            C.Offset(, 1) = "Non présent"
        Else
        C.Offset(, 1) = Teste
        End If
    Next C
End With