Discussion :

[Christophe.c.13]

Bonjour à tous,

Est-il possible dès le lancement d'un UserForm de lancer un timer sans que cela bloque les actions utilisateurs dans le UserForm ?

Je m'explique ...

Voici mon code dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub Workbook_Open()
 
ThisWorkbook.Application.Visible = False
 
UserForm.Show
 
Call Module.Execution
 
End Sub

Ce que je souhaiterai, c'est que le UserForm se lance et que si il n'y a aucune action d'un utilisateur dans le UserForm (Ex : clique sur un bouton) pendant 2min que celui ci se ferme et que la prochaine action soit Call Module.Execution dans ThisWorkbook

Et inversement, le UserForm se lance et si l'utilisateur effectue une action dans celui ci (Ex : clique sur un bouton) avant le timer de 2min que le UserForm reste ouvert


Je vous remercie par avance

[BlueMonkey]

Salut,

Une solution est de rester dans la routine UserForm_Activate() tant que l'une des conditions suivantes n'est pas remplie :
- durée entre affichage de la fenêtre et heure actuelle < 2 minutes
- l'utilisateur a cliqué sur un des boutons

Pour que la USF reste réactive aux actions de l'utilisateur, on appellera DoEvents périodiquement dans la boucle d'attente.

Pour ne pas mobiliser le CPU durant l'attente, on utilisation la fonction de l'API Windows Sleep(<delay en ms>).

Note : tous l'évènement sur lesquels il faut arrêter la fermeture temporisée de l'USF doivent faire isUserAction = True

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
 
Private isUserAction As Boolean
 
Private Sub CommandButton1_Click()
    isUserAction = True
End Sub
 
Private Sub UserForm_Activate()
    isUserAction = False
    Dim showDate As Date
    showDate = Now()
    Do
        DoEvents
        Sleep 100
        DoEvents
        If isUserAction Then Exit Do
    Loop While ((Now() - showDate) < TimeValue("00:02:00"))
 
    If Not isUserAction Then Hide
End Sub

[Christophe.c.13]

Salut BlueMonkey,

Je te remercie non seulement pour ta réactivité mais aussi pour ta solution qui fonctionne parfaitement.

En plus, tu as pris le temps de mettre en forme ton code donc cela m'a permis de bien comprendre le fonctionnement notamment de DoEvents.

Bon week end

[BlueMonkey]

Content que ça fonctionne comme tu veux.
Pour la mise en forme du code c'est un réflexe :
ça ne coûte presque pas de temps à la saisie, et en fait gagner beaucoup à la relecture.

Bon week-end également.