Discussion :

[d_dalcan]

Bonjour à tous,

Voilà mon soucis, j'ai trouvé un script sur le Net qui correspond parfaitement à ce que je veux faire, mais lorsque je le lance, il m'affiche cette erreur : Permission refusée

Merci d'avance à tous pour votre aide


Voici le script :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit 'force all variables to be declared
Const ForWriting = 2
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")
 
Dim objTS 'Text Stream Object
Set objTS = objFSO.OpenTextFile("C:\Output.txt", ForWriting, True)
 
Recurse objFSO.GetFolder("C:\")
objTS.Close()
 
Sub Recurse(objFolder)
    Dim objFile, objSubFolder
 
    For Each objFile In objFolder.Files
        If LCase(objFSO.GetExtensionName(objFile.Name)) = "locky" Then
            objTS.WriteLine(objfile.Path)
        End If
    Next
 
    For Each objSubFolder In objFolder.SubFolders
        Recurse objSubFolder
    Next
End Sub

[pitchalov]

Bonjour,

Il y a de grandes chances pour que ta fonction récursive, que tu fais partir de la racine de C:\, rencontre des dossiers dans lesquels tes privilèges ne te permettent pas de naviguer (des dossiers système par exemple).

Une gestion d'erreur peut t'aider à faire que ton script ne soit pas bloqué. A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Option Explicit 'force all variables to be declared
Const ForWriting = 2
Dim objFSO
Set objFSO = CreateObject("Scripting.FileSystemObject")
 
Dim objTS 'Text Stream Object
Set objTS = objFSO.OpenTextFile("C:\Output.txt", ForWriting, True)
 
Recurse objFSO.GetFolder("C:\")
objTS.Close()
 
Sub Recurse(objFolder)
    Dim objFile, objSubFolder
    On Error Resume Next
    For Each objFile In objFolder.Files
        If Err.Number <> 0 Then
          objTS.WriteLine("Fichier non accessible dans le répertoire " & objFolder.Path)
          Err.Clear
        Else
          If LCase(objFSO.GetExtensionName(objFile.Name)) = "locky" Then
              objTS.WriteLine(objfile.Path)
          End If
        End If
    Next
 
    For Each objSubFolder In objFolder.SubFolders
        If Err.Number <> 0 Then
          objTS.WriteLine("sous-répertoire non accessible dans le répertoire " & objFolder.Path)
          Err.Clear
        Else
          Recurse objSubFolder
        End If
    Next
End Sub

Ou alors le problème peut venir de l'écriture du fichier output à la racine de C:\, qui peut nécessiter une élévation de privilège. Si c'est le cas écris le fichier ailleurs, ou lance le script avec des privilèges administrateur.

Bonne continuation