Coordonnées d'une checkbox

**mathspountz** · 31/05/2013, 11h08

Bonjour à tous,

J'ai un fichier excel avec des checkbox placé dans les cellules d'un tableau. L'utilisateur les coche selon ses besoins.
J'aimerais que via, une macro, excel puisse me renvoyer la valeur des cellules de la première colonne des lignes, où les checkboxs ont été cochées.

Le problème, c'est que le fichier en question a été créé n'importe comment et le nom des checkboxs n'ont aucune logique. De plus, il serait préférable de ne pas trop le modifier.

La question est donc :

Est-il possible, à partir des coordonnées d'une cellule, de selectionner une checkbox ?

Je pense que ce que c'est impossible, mais sait-on jamais. Si quelqu'un à une idée.

**Fred.dz** · 31/05/2013, 14h58

Je ne pense pas non plus que ce soit possible. Je pense que la solution la plus simple est de modifier les noms de tes checkbox. Je suppose que si t'as pas trop envie d'y toucher c'est parce qu'il y a des références à ces checkbox dans le code, mais bon la fonction remplacer devrait rendre le tout pas trop pénible.

**jfontaine** · 31/05/2013, 16h14

Bonjour,

Voici un exmeple de fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Function Cherche_Checkbox(strAddress As String) As String
Dim obj As OLEObject
Dim strRetour As String
 
For Each obj In Me.OLEObjects
 
    If TypeOf obj.Object Is MSForms.CheckBox Then
        If obj.TopLeftCell.Address(False, False) = strAddress Then
            strRetour = obj.Name
        End If
    End If
 
Next
 
Cherche_Checkbox = strRetour
 
End Function

Que l'on utilise comme cela. Retourne le nom de checkbox qui se trouve en A16

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox Cherche_Checkbox("A16")

Et pour cocher ou décocher la checkbox d'une cellule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Coche_decoche "A4"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Coche_decoche(strAddress As String)
Dim obj As OLEObject
 
For Each obj In Me.OLEObjects
 
    If TypeOf obj.Object Is MSForms.CheckBox Then
        If obj.TopLeftCell.Address(False, False) = strAddress Then
            obj.Object.Value = Not obj.Object.Value
        End If
    End If
 
Next
 
End Sub

**mathspountz** · 03/06/2013, 11h17

Woaw ! Je suis impressionné, on peut vraiment tout faire avec excel !

Par contre, il y a un problème que je ne sais pas corriger tout seul car j'avoue que cette fonction dépasse mes compétences :

Quand je la lance, il me met "utilisation incorrect du mot clé : Me". (ligne 5)

J'ai donc changé Me par workbooks("nom du classeur").
Cette fois ci le problème est ligne 6. : "Type défini par l'utilisateur non défini".

J'ai essayé de m'inspirer de ça (http://msdn.microsoft.com/en-us/libr...(v=vs.80).aspx) pour corriger mais je n'y arrive pas...

**jfontaine** · 03/06/2013, 12h22

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each obj In Me.OLEObjects

Ici Me est un raccourci pour nommer la feuille quand le code se trouve sur la feuille contenant les objets
Si ton code se trouve dans un module, il faut stipuler le nom de la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each obj In Sheets("Feuil1").OLEObjects

**mathspountz** · 03/06/2013, 13h24

Merci pour ton message.
Effectivement j'avais mis le code dans un module. J'ai donc changé me par le workbooks("workbook").sheets("feuille") mais j'ai toujours un problème ligne 6.

"Type défini par l'utilisateur non défini".

**Marc-L** · 03/06/2013, 13h35

Bonjour,

une p'tite incusrion pour juste signaler la non existence de TypeOf en VBA 2003 ! (à vérifier aussi dans les versions postérieures)

Voir peut-être du côté de la fonction TypeName …

_______________________________________________________________________________

Merci de cliquer sur

pour chaque message ayant aidé puis sur

pour clore cette discussion …

**jfontaine** · 03/06/2013, 13h55

une p'tite incusrion pour juste signaler la non existence de TypeOf en VBA 2003 ! (à vérifier aussi dans les versions postérieures)

Je ne suis pas d'accord,TypeOf fonctionne aussi sur Excel 2003

**mathspountz** · 03/06/2013, 14h00

Arf effectivement en recherchant la fonction avec control espace je n'ai qu'une fonction typename mais pas de typeof...

Du coup ça ne va pas être possible ?

**jfontaine** · 03/06/2013, 14h06

la formule DATEDIF n'est pas documenté et n’apparaît pas dans la liste des formules, et pourtant elle existe et fonctionne très bien

As tu essayé le code?

**mathspountz** · 03/06/2013, 14h09

Oui et j'ai une erreur à la sixième ligne :

"Type défini par l'utilisateur non défini".

**Marc-L** · 03/06/2013, 14h16

Même message lors de la compilation !

Et comme je n'ai pas trouvé TypeOf ni dans l'aide interne, ni en ligne, ni dans le MSDN Excel VBA 2003 …

Y-a-t-il une référence à activer ? Ou bien une histoire de parenthèses manquantes ?

**jfontaine** · 03/06/2013, 14h21

Ci joint un fichier qui fonctionne sur mon poste en excel 2003.

Fonctionne-t-il sur le tien ?

VBA - TypeOf -Coche et décoche.xls

**Marc-L** · 03/06/2013, 14h24

Donc autant pour moi pour le TyPeOf même s'il n'est vraiment pas documenté …

En fait mathspountz, il faut dans le menu Outils, Références cocher Microsoft Forms 2.0 Object Library
pour ne plus avoir cette erreur de compilation provoquée par MSForms …

NB : selon où je me trouve, je ne peux télécharger pour des raisons de sécurité …

**mathspountz** · 03/06/2013, 14h34

Arf je ne trouve que microsoft activeX data objects 2.0 library.

Je suppose que ce n'est pas le même ? (j'ai essayé sans succès).

J'ai rien dans microsoft + f dans la liste...

**mathspountz** · 03/06/2013, 14h38

J'ai pourtant essayé ton fichier jfontaine, qui fonctionne. Ca coche et décoche les cases...

Mais tes checkboxs sont peut-être un peu différentes des miennes. Je t'ai copier coller trois checkbox qui viennent de mon fichier.

**jfontaine** · 03/06/2013, 14h58

Dans ton cas, ce ne sont pas des Checkbox (VBA) mais des Cases à Cocher (Formulaire).
Ce n'est pas du tout le même code.

**mathspountz** · 03/06/2013, 15h53

Mince désolé je ne savais pas qu'il y avait une différence entre les deux...

Pourtant avec l'enregistreur de macro j'avais essayé d'en copier coller une pour voir ce que c'était :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    ActiveSheet.Shapes("Check Box 166").Select
    Selection.Copy
    Range("X30:AE30").Select
    ActiveSheet.CheckBoxes.Add(234.75, 389.25, 25.5, 17.25).Select
    ActiveSheet.Paste

Heu... Du coup, ça ressemblerait quand même au premier code ou faut tout revoir ?

**jfontaine** · 03/06/2013, 16h14

Peut être comme cela, mais il me manque le code pour cocher
De plus le type 8 est pour tous les objets formulaire alors ca marchera que s'il y que des cases à cocher

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Coche_decoche(strAddress As String)
Dim obj As Shape
 
For Each obj In Me.Shapes
    If obj.Type = 8 Then
        If obj.TopLeftCell.Address(False, False) = strAddress Then
            'Code pour cocher
            obj.Select
            If Selection.Value = xlOn Then
                Selection.Value = xlOff
            Else
                Selection.Value = xlOn
            End If
        End If
    End If
Next
 
End Sub

EDIT : Ajout du code pour cocher

**mathspountz** · 03/06/2013, 16h27

Merci mille fois ça fonctionne !!!

Ca c'est fort bravo !

Coordonnées d'une checkbox [XL-2003]

Macros et VBA Excel

Discussions similaires

Partager

Partager