Discussion :

[jacfld49]

Bonsoir le forum,

j'ai ce code qui fonctionne très bien (fait par papounet) mais comment faire pour qu'il fonctionne pour toute les feuilles
merci d'avance
jacky

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub MasquerLignes()
Dim Cel As Range, Plage As Range, sh As Object
 
For Each sh In Sheets
  If sh.Name Like "CG SD*" Then
    With sh
      For Each Cel In .Range("D:D").SpecialCells(xlCellTypeConstants)
        If Cel.Value Like "Dos*" And Cel.Offset(1, 0) = "" Then
          If Plage Is Nothing Then
            Set Plage = Cel.Offset(-1, 0).Resize(10, 1)
            Else
            Set Plage = Application.Union(Plage, Cel.Offset(-1, 0).Resize(10, 1))
          End If
        End If
      Next
    End With
    Plage.EntireRow.Hidden = True
    Set Plage = Nothing
  End If
Next
End Sub

[BenjGe]

que veux tu dire par "marcher sur toutes les feuilles"

Actuellement la procédure tourne sur toutes les feuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each sh In Sheets

en tout cas tu auras un bug si ton classeur passe par une feuille qui n'est pas une feuille de calcul.

Utilise plutôt:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each sh In WorkSheets

par contre le contenu de la boucle ne s'exécute que si le nom de la feuille correspond au motif "CG SD*":

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If sh.Name Like "CG SD*" Then
...
End If

ce test l'empêche de s'exécuter sur toutes les feuilles
si tu ne le souhaites pas il faut commenter les lignes IF et END IF

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub MasquerLignes()
Dim Cel As Range, Plage As Range, sh As Worksheet
 
For Each sh In WorkSheets
  'If sh.Name Like "CG SD*" Then
    With sh
      For Each Cel In .Range("D:D").SpecialCells(xlCellTypeConstants)
        If Cel.Value Like "Dos*" And Cel.Offset(1, 0) = "" Then
          If Plage Is Nothing Then
            Set Plage = Cel.Offset(-1, 0).Resize(10, 1)
            Else
            Set Plage = Application.Union(Plage, Cel.Offset(-1, 0).Resize(10, 1))
          End If
        End If
      Next
    End With
    Plage.EntireRow.Hidden = True
    Set Plage = Nothing
  'End If
Next
End Sub

[jacfld49]

Bonsoir le forum,Benjîle,

cela fonctionne sur les feuille qui sont CF SD ou CG SD mais ne fonctionne pas sur les feuilles CF D ou CG D mais je ne pense que cela viennent du format du Nom mais plutot du code car il bug et me met :erreur d'éxécution '91' et variable objet ou variable de bloc non définie et quand je fais débogage, il me surligne cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Plage.EntireRow.Hidden = True

je pense qu'il y a une erreur de plage mais à part que sur les feuilles ou cela bug, les tableaux s'arrêtent à la ligne 25, je ne vois pas
merci de votre aide
jacky

[BenjGe]

quel est le code qui produit une erreur? celui que je vous fournis ou celui vous donnez au début de la discussion?

si il s'agit du mien voici une autre proposition:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub MasquerLignes()
Dim Cel As Range, Plage As Range, sh As Object
 
For Each sh In Sheets
  If sh.Name Like "CG SD*" Then
    With sh
      For Each Cel In .Range("D:D").SpecialCells(xlCellTypeConstants)
        If Cel.Value Like "Dos*" And Cel.Offset(1, 0) = "" Then
          If Plage Is Nothing Then
            Set Plage = Cel.Offset(-1, 0).Resize(10, 1)
            Else
            Set Plage = Application.Union(Plage, Cel.Offset(-1, 0).Resize(10, 1))
          End If
        End If
      Next
    End With
    if Not(Plage is nothing) then  Plage.EntireRow.Hidden = True
    Set Plage = Nothing
  End If
Next
End Sub

La procédure plante sur certaines feuilles parce que dans chacune elle cherche dans la colonne D parmi les cellules contenant des constantes (et pas de résultats de formules ni des cellules vides)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
  For Each Cel In .Range("D:D").SpecialCells(xlCellTypeConstants)

dont le début commence par les lettres "Dos" et dont la cellule en dessous ne contient rien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  If Cel.Value Like "Dos*" And Cel.Offset(1, 0) = "" Then

si dans ces feuilles il ne trouve aucune cellule de ce type alors que la colonne D contient des constantes l'objet Plage ne sera jamais incrémenté et vaudra Nothing ce qui fait planter la ligne que vous indiquez

[jacfld49]

Bonjour le forum, benjile,

oui, c'est exactement cela, j'avais vu que c'était les feuilles ou lorsque les tableaux étaient rempli et qu'ensuite il n'y avait pas de tableau vide derrière que le code plantait, donc j'ai ajouté un tableau derrière ou j'ai mis les écriture en blanc , aucune bordure et aucun fond comme cela, il y a toujours un mot Dos* derrière et du coup cela fonctionne maintenant , mais je vais essayer ton nouveau code pour voir
merci beaucoup
jacky