Discussion :

[létudiant_access]

Bonjour,

Mon probleme est le suivant :
Je souhaite trouver le numéro des lignes de ma colonne A qui contiennent une valeur test et les stocker dans un tableau.

J'arrive à faire ce que je veux mais c'est LONG! (je vais devoir chercher sur 500 000 lignes environ. Pouvez vous m'aider à optimiser la chose ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Public Sub lookfor()
    Dim row_max As Long
    Dim k As Long
    Dim index() As Long
    Dim compt As Long
    Dim number As Long
    Dim test As String
    test = "valeur recherchée"
    compt = 2
    number = 0
    Erase index()
    row_max = Feuil1.Cells(Rows.Count, "A").End(xlUp).Row
    Do
         If Feuil1.Range("A" & compt).Value = test Then
            number = number + 1
            ReDim Preserve index(number)
            index(number) = Feuil1.Range("A" & compt).Row 
         End If
        compt = compt + 1
    Loop Until compt = row_max + 1 
End Sub

Des idées pour accélérer la chose ?


Merci

[gFZT82]

Bonjour,

Tu peux gagner en temps si tu utilises un tableau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Sub lookfor()
Dim i As Long, Number As Long
Dim Tablo()
Dim index() As Long
Dim test As String
    test = "valeur recherchée"
    With Worksheets("Feuil1")
        Tablo = .Range("A2:A" & .Cells(Rows.Count, "A").End(xlUp).Row).Value
        For i = 1 To UBound(Tablo)
            If Tablo(i, 1) = test Then
                ReDim Preserve index(Number)
                index(Number) = i + 1
                Number = Number + 1
            End If
        Next i
    End With
End Sub

Cordialement.

[létudiant_access]

Merci beaucoup ! Vitesse x5 !

D'autres idees ?