Discussion :

[ASACAD]

Bonjour,

Je cherche à ajouter sur un graphe déjà existant une courbe à partir de données présentes sur un classeur différent de celui où se trouve le graphique.
Je ne connais quasiment rien en VBA, j'utilise donc l'enregistrement de macro pour mon programme.

Le problème c'est que ce second classeur peut changer dans le temps en fonction des choix de l'utilisateur. Je suis donc obligé d'appeler dans la création de la courbe le nom du second classeur par une variable. Voici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Workbooks.Open Filename:=dat
    nom = ActiveWorkbook.Name
...
    ActiveSheet.ChartObjects("Graphique 1").Activate
    ActiveChart.SeriesCollection.NewSeries
    ActiveChart.SeriesCollection(2).Name = "=""2%"""
    ActiveChart.SeriesCollection(2).XValues = "=Résultats!$A$5:$A$29"
    ActiveChart.SeriesCollection(2).Values = _
        "='[nom.xls]Tableaux'!$D$35:$D$59"

dat correspond au contenu d'une cellule contenant l'adresse du fichier à ouvrir.
En faisant ça, j'obtiens une courbe sur le graphique en question, mais toutes les valeurs sont à 0. Savez-vous ce qui doit remplacer [nom.xls] afin que les données soient renseignées correctement ?

Merci à vous.

[mercatog]

Si Dat contient le nom complet du fichier à ouvrir
Si les données récupérées sont issues de la feuille Tableaux du fichier à ouvrir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub MAJgraphique()
Dim Grf As ChartObject
Dim Wbk As Workbook
Dim Dat As String
 
'Dat = nom complet du fichier à ouvrir
Application.ScreenUpdating = False
If Dat <> "" Then
    If Dir(Dat) <> "" Then
        Set Wbk = Workbooks.Open(Dat)
        Set Grf = ThisWorkbook.Worksheets("Résultats").ChartObjects("Graphique 1")
        With Grf.Chart.SeriesCollection.NewSeries
            .Name = "=""2%"""
            .XValues = "=Résultats!$A$5:$A$29"
            .Values = "='[" & Wbk.Name & "]Tableaux'!$D$35:$D$59"
            'La ligne suivante peut être supprimée si on veut garder le lien avec le fichier Dat
            .Values = .Values
        End With
        Set Grf = Nothing
        MsgBox "Mise à jour graphique terminée"
        Wbk.Close False
    Else
        MsgBox "Fichier " & Dat & " introuvable"
    End If
End If
End Sub

[ASACAD]

Merci beaucoup ! Ca marche !