Discussion :

[ronierserge]

Bonjour à tous,

Je me demande s'il y a une solution pour mettre en forme des cellules (que ce soit dans une proc tabulate ou autre) d'un tableau selon les conditions d'autres cellules (pas forcément les colonnes/lignes auxquelles appartiennent les cellules).

Je m'explique avec un exemple assez simple.

A partir des données brutes :



Pourrait-on obtenir un reporting de la forme :



Tel que :
1. remplissage de cellules avec du rouge quand les valeurs sont négatives
2. police de couleur rouge quand le stock du fournisseur dans le pays indiqué est géré par un sous-traitant

Le point 1. ne me pose pas de problème, car c'est direct avec un format.

C'est plutôt le point 2. qui m'intrigue un peu.

Merci beaucoup de votre aide !

[wielki]

Oui cela doit être possible

deux pistes à concrétiser

1) je n'ai jamais essayé le multilabel sur des styles de couleur
pour background ou foreground
cependant cela me fait penser qu'en 9.3 on peut maintenant utiliser
des fonctions à droite du signe égal dans des values....

2) créer son petit template de table
et utiliser cette facilité en la mélangeant à la solution de votre 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
47     cellstyle     180 < t    as {font_style=italic background=red },
48                   100 < t <= 180   as {font_style=italic background=salmon },
49                   50 <= c <= 100   as {font_style=italic background=green
49 ! foreground=black}

ceci est accepté pour la compilation d'un template
et le cellstyle s'applique à la colonne t mais je teste une valeur de la colonne c
cellstyle travaille a postériori sur des résultats pour changer leur présentation
donc dans second temps par rapport à habillage par le format

A tester

Pour faire un template de table inspirez-vous de Kevin D Smith
Proc template tables from scratch


AW

[ronierserge]

Merci Wielki !

Si j'ai bien compris, dans votre proposition 2, les variables t et c représentent bien des colonnes, selon lesquelles, on souhaite mettre en forme une même cellule ?

Je me demande également si la proc template pourrait être utilisée pour un report qui pourrait varier de taille (nombre de colonnes / de lignes).

Merci encore !!

[edward carnby]

hello,

moi, j'aurais :
1/ recodé la variable ss_traitant en numérique.
2/ utilisation d'un proc format pour les valeurs négatives.
3/ utilisation d'un call define pour la mise en forme conditionnelle

exemple de code à adapter ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
/* jeu de données */
data matable;
input frn $2. pays :$10. stock :percent5. ss_traitant $3.;
if ss_traitant = "oui" then ss_traitant2 = 0;
else ss_traitant2=1;
cards;
F1 France -2% oui
F1 Allemagne 5% non
F1 Suisse 14% oui
F2 France 10% non
F2 Allemagne -1% non
F2 Suisse 7% non
;
run;
 
/* format des valeurs négatives */
PROC FORMAT;
value bgcolor low-<0="lightpink";
RUN;
 
/* la proc report avec les call define */
proc report data=matable;
column ("fournisseur" frn) pays, (ss_traitant2 stock);
define frn / group '';
define pays / across '';
define stock / sum '' format=percent5. STYLE={BACKGROUND=bgcolor.};
define ss_traitant2 / sum '' noprint;
compute stock;
	IF _C2_ = 0 THEN CALL DEFINE('_C3_','style','style=[foreground=red]');
	IF _C4_ = 0 THEN CALL DEFINE('_C5_','style','style=[foreground=red]');
	IF _C6_ = 0 THEN CALL DEFINE('_C7_','style','style=[foreground=red]');
endcomp;
run;

[ronierserge]

Hello et merci beaucoup Edward Carnby !

C'est exactement ça !

Merci encore !