Discussion :

[Vishnou]

Bonjour,

Je dispose d'une macro qui permet lorsqu'elle est exécutée sur Excel 2010 d'ouvrir la fenêtre d'impression et de préparer le document à imprimer sans la couleurs de fonds sur les cellules de ma feuille pour que je n'ai plus qu'a cliquer sur Imprimer.

Macro actuelle:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Impression_sans_couleurs()
  Dim temp1(), temp2()
  For Each c In ActiveSheet.UsedRange
    If c.Interior.ColorIndex <> xlNone Then
       n = n + 1
       ReDim Preserve temp1(1 To n)
       ReDim Preserve temp2(1 To n)
       temp1(n) = c.Address
       temp2(n) = c.Interior.ColorIndex
       c.Interior.ColorIndex = xlNone
    End If
  Next c
  ActiveSheet.PrintPreview   ' ou ActiveSheet.PrintOut
  For i = 1 To n
    Range(temp1(i)).Interior.ColorIndex = temp2(i)
  Next i
End Sub

Par contre je suis obliger de définir ma zone d'impression manuellement sur feuille.
Comment puis-je définir ma zone d'impression (qui doit être de A1 à L60)
Merci pour votre aide.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.PageSetup.PrintArea = "A1:L60"

[Vishnou]

Je ne suis pas expert en code, pourriez-vous svp m'indiquer à quel endroit je dois mettre celui-ci?
Merci

Autre question: Il faut que la macro puisse cocher la case ajuster à une seule page, car cette action est également faite manuellement.

Merci de votre soutien.

[mercatog]

Sers toi de l'enregistreur de macro, ça t'aidera dans de tels cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Impression_sans_couleurs()
Dim i As Long, n As Long
Dim Temp1(), Temp2()
Dim c As Range
 
For Each c In ActiveSheet.UsedRange
    If c.Interior.ColorIndex <> xlNone Then
        n = n + 1
        ReDim Preserve Temp1(1 To n)
        ReDim Preserve Temp2(1 To n)
        Temp1(n) = c.Address
        Temp2(n) = c.Interior.ColorIndex
        c.Interior.ColorIndex = xlNone
    End If
Next c
With ActiveSheet.PageSetup
    .PrintArea = "A1:L60"
    .Zoom = False
    .FitToPagesWide = 1
    .FitToPagesTall = 1
End With
ActiveSheet.PrintPreview                           ' ou ActiveSheet.PrintOut
For i = 1 To n
    Range(Temp1(i)).Interior.ColorIndex = Temp2(i)
Next i
End Sub

[Vishnou]

Merci, la macro fonctionne trés bien et en plus réactivité exemplaire. RAS

[mercatog]

Je préfère celle-là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub Impression_sans_couleurs()
Dim i As Long, n As Long
Dim c As Range
Dim Temp()
 
With ActiveSheet
    For Each c In .UsedRange
        If c.Interior.ColorIndex <> xlNone Then
            n = n + 1
            ReDim Preserve Temp(1 To 2, 1 To n)
            Temp(1, n) = c.Address
            Temp(2, n) = c.Interior.ColorIndex
            c.Interior.ColorIndex = xlNone
        End If
    Next c
 
    With .PageSetup
        .PrintArea = "A1:L60"
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
    End With
    .PrintPreview                                  ' ou ActiveSheet.PrintOut
 
    If n > 0 Then
        For i = 1 To n
            .Range(Temp(1, i)).Interior.ColorIndex = Temp(2, i)
        Next i
    End If
    .PageSetup.PrintArea = ""
End With
End Sub