Discussion :

[joninho]

Bonjour, je suis à la recherche d'un script ou d'une commande qui permet de supprimer tous les fichiers qui sont dans des répertoires et des sous-répertoires mais sans supprimer l'arborescence.

Est-ce que quelqu'un peut m'aider ? Ce serait super cool

[PBELL]

Bonjour Joninho,
La solution en AppleScript passe par l'appel à une fonction de façon récursive.
Cela consiste à appeler une fonction (en l'occurrence qui supprime les fichiers et fait la liste des sous-dossiers) et que cette fonction s'appelle elle-même pour descendre dans l'arborescence :

Voici un script qui fait ce que tu demandes avec des commentaires :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
-- Suppression des fichiers dans l'arborescence des sous dossiers
-- en conservant les dossiers et sous dossiers
 
tell application "Finder"
	set Dossier_en_Cours to ((choose folder with prompt "Choisissez le dossier principal :" without invisibles) as alias) as string
	display dialog "Attention : L'opération est irreversible !"
	-- de facto si l'utilisateur clique sur le bouton Annuler, le script s'arrête
 
	set Liste_Sous_Dossiers to (every folder of folder Dossier_en_Cours) as alias list
end tell
-- appelle la sous routine récursive
Nettoie_Dossier(Dossier_en_Cours, Liste_Sous_Dossiers)
-- fin du programme principal
 
-- Sous routine appelée par récursivité
-- Arguments : Dossier_en_Cours et liste_Sous_Dossier contenus dans ce dossier
on Nettoie_Dossier(Doss, Liste_Dos)
	-- supprime les fichiers du Dossier Doss 
	tell application "Finder" to delete every file of folder Doss -- suppression des fichiers de ce niveau
	repeat with Un_Dossier in Liste_Dos
		-- pour chaque sous dossier, liste les sous - sous dossiers
		tell application "Finder" to set Liste_Sous_Sous_Dossiers to (every folder of folder Un_Dossier) as alias list
		-- appelle cette sub routine en recursivite pour répéter l'opération pour chaque sous dossier trouvé
		Nettoie_Dossier(Un_Dossier, Liste_Sous_Sous_Dossiers)
	end repeat
end Nettoie_Dossier

PS : par habitude j'évite la récursivité sur les tell Finder/end tell. c'est la raison pour laquelle j'utilise le Tell par instruction dans le sous routine.

Cordialement

[joninho]

Super, merci beaucoup ! J'avais déjà développé une appli du genre mais jamais en AppleScript.

Encore merci !