Discussion :

[sagull]

Bonjour,
Je dois récupérer la valeur d'une cellule dans un fichier externe fermé.
le nom du fichier ou se trouve la valeur correspond à la valeur d' une cellule du fichier actif (B10). Pour le nom d'onglet (toujours dans le fichier externe), celui ci est parfois amené à changer de nom et je ne peux donc pas utiliser ce paramétre dans ma macro et voudrais plutôt utiliser le N° d'ordre de l'onglet qui lui ne changera pas. Voici concrétement mes lignes de code :

Cette ligne fonctionne avec le nom d'onglet (ONGLET N°3)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
cells(1, 1).Value = ExecuteExcel4Macro("'c:\mondossier\monsousdossier\[" & (ThisWorkbook.Sheets("MONONGLET").Cells(10, 2).Value) & "]ONGLET N°3'!R1C12")

Cette ligne ne fonctionne pas avec le N° d'ordre (Sheets(3))car je ne trouve pas la bonne syntaxe (si toutefois c'est possible?)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Cells(1, 1).Value = ExecuteExcel4Macro("'c:\mondossier\monsousdossier\[" & (ThisWorkbook.Sheets("MONONGLET").Cells(10, 2).Value) & "]  Sheets(3)'! R1C12")

Un grand merci à qui pourra m'aiguiller vers la solution

[Edit]
Notification par mail....

[kiki29]

Salut, je crains que cela ne soit pas possible, il faut utiliser le nom d'onglet de la feuille, voir ici et là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
 
Private Function ExtraireValeur(sDossier As String, _
                                sFichier As String, _
                                sFeuille As String, _
                                sCellule As String)
Dim sArgument As String
    sDossier = Replace(sDossier, "'", "''")
    sFichier = Replace(sFichier, "'", "''")
    sArgument = "'" & sDossier & "[" & sFichier & "]" & sFeuille & "'!" & Range(sCellule).Address(, , xlR1C1)
    ExtraireValeur = ExecuteExcel4Macro(sArgument)
End Function
 
Sub Tst()
Dim Dossier As String
Dim Fichier As String
Dim Feuille As String
Dim Cellule As String
    Dossier = "C:\Transfert\Test\"
    Fichier = "Test.xls"
    Feuille = "Feuil2"
    Cellule = "A1"
    ActiveSheet.Cells(1, 1) = ExtraireValeur(Dossier, Fichier, Feuille, Cellule)
End Sub

[sagull]

Bonsoir,
Merci kiki29 ton code permet surement d'aboutir mais je suis entrain de l'adapter à ma config. et j'ai un peu de difficultés. pas d'arret de macro mais un #REF! dans la cellule, j'ai l'impression que ça bug au niveau de:
Range(sCellule).Address car en ligne 23 les valeurs sont bien reconnues sauf cellule

[kiki29]

Salut, ici cela fonctionne sans problème, ton "adaptation" est donc fautive. Je ne vois pas d'ailleurs ce qu'il y a à adapter.

[sagull]

Bonjour,
Effectivement Kiki29 ton code fonctionne trés bien tel que tu l'a publié mais mon probléme persiste dans le sens où le paramétre "Feuille" doit correspondre, chez moi, à un N° d'ordre de feuille dans le fichier fermé (pas de nom dans la macro car il change réguliérement) et c'est cette foutue syntaxe que je ne parviens pas à trouver.

ce qui donne chez moi (avec un prob sur paramétre Feuille bien sure)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
    Dossier = "C:\Mondossier\Monsousdossier\"
    Fichier = Cells(4, 2).Value
    Feuille =  Sheets(2).Name '(du fichier fermé, c'est là mon soucis )
    Cellule = "A1"
    Cells(2, 2) = ExtraireValeur(Dossier, Fichier, Feuille, Cellule)

Merci encore

[kiki29]

Re,

je crains que cela ne soit pas possible, il faut utiliser le nom d'onglet de la feuille

donc "Feuil3" ou autre
Voir les liens proposés dans le post# 2

Sinon passer par qqch d'alambiqué comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Option Explicit
 
Dim Ar() As String
 
Private Function ExtraireValeur(sDossier As String, _
                                sFichier As String, _
                                sFeuille As String, _
                                sCellule As String)
Dim sArgument As String
    sDossier = Replace(sDossier, "'", "''")
    sFichier = Replace(sFichier, "'", "''")
    sArgument = "'" & sDossier & "[" & sFichier & "]" & sFeuille & "'!" & Range(sCellule).Address(, , xlR1C1)
    ExtraireValeur = ExecuteExcel4Macro(sArgument)
End Function
 
Sub Tst()
Dim Dossier As String
Dim Fichier As String
Dim Feuille As String
Dim Cellule As String
Dim sFichier As String
 
    Dossier = "C:\Transfert\Test\"
    Fichier = "Test.xls"
 
    sFichier = Dossier & Fichier
    ListeNomFeuilles sFichier
    '    Ar() contient le nom des feuilles dans l'ordre ALPHABETIQUE 
    '    et non dans l'ordre des positions du classeur testé
    Feuille = Ar(3)
 
    Cellule = "A1"
    ActiveSheet.Cells(1, 1) = ExtraireValeur(Dossier, Fichier, Feuille, Cellule)
End Sub
 
Private Sub ListeNomFeuilles(sNom As String)
Dim Conn As Object
Dim Cat As Object
Dim FeuilleXL As Object
Dim i As Long
 
    Erase Ar
    Set Conn = CreateObject("ADODB.Connection")
    Set Cat = CreateObject("ADOX.Catalog")
 
    Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & sNom & ";Extended Properties=Excel 8.0;"
 
    Set Cat.ActiveConnection = Conn
 
    For Each FeuilleXL In Cat.Tables
        Select Case Right$(FeuilleXL.Name, 1)
            Case "$"
                i = i + 1
                ReDim Preserve Ar(i)
                Ar(i) = Left$(FeuilleXL.Name, Len(FeuilleXL.Name) - 1)
            Case "'"
                ' Nom de feuille comportant des espaces
                i = i + 1
                ReDim Preserve Ar(i)
                Ar(i) = Mid$(FeuilleXL.Name, 2, Len(FeuilleXL.Name) - 3)
        End Select
    Next FeuilleXL
 
    Conn.Close
    Set Conn = Nothing
    Set Cat = Nothing
End Sub