Discussion :

[Tomtom45]

Bonjour à tous !

Après plusieurs heure de recherche infructueuse je me tourne vers ce forum.

Je suis à la recherche d'une méthode afin de séparer une ligne par bloc de 15 colonnes et d'ensuite réaligner ces colonnes. Pour être plus clair, j'ai un tableau de donnée :

Nom A ;Prénom A ;Tél A ;Adresse A ;Nom B ;Prénom B ;Tél B Adresse B ;
Nom A2; Prénom A2 ;TélA2 ;Adresse A2 ;Nom B2 ;PrénomB2 ;Tél B2;..
Nom A3; Prénom A3;... ;Nom B3; Prénom B3;...


Et j'aimerais ces données sous la forme :

Nom A ;Prénom A ;Tél A ;Adresse A;
Nom A2; Prénom A2 ;TélA2 ;Adresse A2
Nom A3; Prénom A3,...
Nom B ;Prénom B ;Tél B Adresse B ;
Nom B2 ;PrénomB2 ;Tél B2;..
Nom B3...

C'est a dire séparer mes lignes par bloc. Dans mon exemple ca serait par bloc de quatre colonnes et 3 lignes et ensuite les aligner...

Je recherche cela car j'aimerais couper ces quelques longues lignes et les mettre en colonnes afin d'avoir chaque catégorie A B C... l'une en dessus de l'autre au lieu de les avoir aligner. En d'autres mots, au lieu d'avoir mes blocs de données en lignes A11 A12 A13 A14B11 B12 B13 B14 C11 C12 C13 C14...
A21 A22 A23 A24 B21 B22 B23 B24 C21 C22 C23 C24...

J aimerais avoir

A11 A12 A13 A14
A21 A22 A23 A24
B11 B12 B13 B14
B21 B22 B23 B24
C11 C12 C13 C14
C21 C22 C23 C24
...

Est ce que mes explications sont assez clair ?

Enfin j'espère que vos lumières pourrons m'aider à résoudre mon problème !

Merci d'avance !

[mercatog]

Bonjour, ci-après code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Reorganiser()
Const X As Byte = 4                                'Nombre de colonnes dans un bloc
Const Y As Byte = 3                                'Nombre de lignes dans un bloc
Const DEB As Integer = 2                           'Ligne de début
Dim LastCol As Integer, i As Integer
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")                          'A Adapter
    LastCol = .Cells(DEB, .Columns.Count).End(xlToLeft).Column
    If LastCol > X Then
        For i = X + 1 To LastCol Step X
            .Range(.Cells(DEB, i), .Cells(DEB + Y, i + X - 1)).Cut .Cells(.Rows.Count, 1).End(xlUp)(2)
        Next i
    End If
End With
End Sub

[gFZT82]

Bonjour,

Une autre version pour plusieurs blocs lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub test()
Dim DerLig As Long, Ligne As Long
Dim DerCol As Integer, Col As Integer
Const BlocLignes = 3
Const BlocColonnes = 15
    Application.ScreenUpdating = False
    With Worksheets("Feuil1")
        DerLig = .Range("A" & Rows.Count).End(xlUp).Row
        DerCol = .Cells(1, Columns.Count).End(xlToLeft).Column
        For Ligne = DerLig - BlocLignes + 1 To 1 Step -BlocLignes
            For Col = DerCol - BlocColonnes * 2 + 1 To 1 Step -BlocColonnes
                .Cells(Ligne, Col).Resize(BlocLignes, BlocColonnes).Cut
                .Cells(Ligne, DerCol - BlocColonnes + 1).Resize(BlocLignes, BlocColonnes).Insert Shift:=xlShiftDown
            Next Col
        Next Ligne
        .Cells(1, DerCol - BlocColonnes + 1).Resize(DerLig * DerCol / BlocColonnes, BlocColonnes).Cut .Cells(1, 1)
    End With
End Sub

Cordialement.

[Tomtom45]

Mille Merci à vous mercatog et gFZT82 !!

Je viens de tester votre code et c'est exactement ce que je voulais !

Je ne sais comment vous remercier d'avantage !

Excellent dimanche à vous !