Discussion :

[auberns]

Bonjour,

J'ai écrit la macro suivante qui crée un fichier pdf (par l'intermédiaire de PDFCreator en mode autosave c'est-à-dire sans l'intervention de l'utilisateur). Le fichier pdf a le même nom que la feuille Excel et est sauvegardé dans le même répertoire que la feuille Excel.

Le problème est que la macro marche quand je suis en mode édition debug en lançant la macro pas à pas. Par contre en mode normal, elle ne marche pas.

Pouvez-vous m'aider à régler ceci ?

Merci
Nicolas

Voici la macro en question:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private Declare Sub Sleep Lib "kernel32.dll" (ByVal dwMilliseconds As Long)
 
Sub ToPdf()
 
  Set pdfjob = CreateObject("PDFCreator.clsPDFCreator")
  NomExcel = ActiveWorkbook.Name
  NomPdf = Left(NomExcel, Len(NomExcel) - 4)
  With pdfjob
  If .cStart("/NoProcessingAtStartup") = False Then 
       MsgBox "Can't initialize PDFCreator.", vbCritical + vbOKOnly, "PrtPDFCreator"
       Exit Sub
  End If
 
  .cOption("UseAutosave") = 1
  .cOption("UseAutisaveDirectory") = 1
  .cOption("AutosaveDirectory") = ActiveWorkbook.Path
  .cOption("AutosaveFilename") = NomPdf
  .cOption("AutosaveFormat") = 0            ' 0 = pdf
  .cClearCache
  End With
  ActiveWorkbook.Sheets("TABLE").PrintOut Copies:=1, ActivePrinter:="PDFCreator"
 
  Do Until pdfjob.cCountOfPrintjobs = 1
      DoEvents
      Sleep 1000
  Loop
 
  With pdfjob
  .cDefaultprinter = DefaultPrinter
  .cClearCache
  .cClose
  End With
  Set pdfjob = Nothing
 
End Sub

[Daniel.C]

Bonjour,

Y a-t-il une erreur; si oui, laquelle ?

[auberns]

Je ne comprends vraiment pas pourquoi cela ne marche pas en mode normal. Quelqu'un pourrait au moins essayer la macro en modes debug et normal pour me confirmer qu'il y a un problème !! Peut-être le problème vient de ma configuration système.

Nicolas

[Daniel.C]

C'est beau les monologues... réponds au moins aux questions qu'on te pose ! Perso, je ne peux pas tester faute de PdfCreator.

[kiki29]

Salut, ceci fonctionne chez moi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Option Explicit
 
Sub ToPdf()
Dim pdfjob As Object
Dim NomExcel As String
Dim NomPdf As String
 
    Set pdfjob = CreateObject("PDFCreator.clsPDFCreator")
    NomExcel = ThisWorkbook.Name
    NomPdf = Left$(NomExcel, Len(NomExcel) - 4) & ".pdf"
 
    With pdfjob
        If .cStart("/NoProcessingAtStartup") = False Then
            MsgBox "Can't initialize PDFCreator.", vbCritical + vbOKOnly, "PrtPDFCreator"
            Exit Sub
        End If
 
        .cOption("UseAutosave") = 1
        .cOption("UseAutisaveDirectory") = 1
        .cOption("AutosaveDirectory") = ThisWorkbook.Path & "\"
        .cOption("AutosaveFilename") = NomPdf
        .cOption("AutosaveFormat") = 0
        .cClearCache
    End With
 
    ThisWorkbook.Sheets("TABLE").PrintOut Copies:=1, ActivePrinter:="PDFCreator"
 
    Do Until pdfjob.cCountOfPrintjobs = 1
        DoEvents
    Loop
    pdfjob.cPrinterStop = False
 
    Do Until pdfjob.cCountOfPrintjobs = 0
        DoEvents
    Loop
 
    pdfjob.cClose
    Set pdfjob = Nothing
 
End Sub

Il peut être judicieux d'avoir également ceci sous la main

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub KillPDFCreator()
Dim RetVal As Long
    RetVal = Shell("Taskkill /im PDFCreator.exe /f", 0)
End Sub

[auberns]

Daniel, je veux bien répondre à ta question "y a-t-il une erreur ?": oui, il y a une erreur vu que cela ne marche pas. Par contre si j'ai posté, c'est d'une que je n'ai pas trouvé l'erreur et de deux, que je n'ai pas trouvé de réponse à mon problème en faisant des recherches sur internet.

Et ni ma réponse ni ta 1ère question ne font avancer le schmilblick. La question plus générale serait: y a-t-il un paramètre qui change entre le mode debug et le mode normal sachant que j'ai mis une fonction sleep pour régler les problèmes de temps d'attente du programme pdf creator.

Merci quand même pour ta contribution hautement résolutive.
Nicolas

Merci kiki29. Je testerai cela demain au travail (je n'ai pas de licence office chez moi). Je reviendrai pour dire si cela marche correctement.

[Invité]

Bonjour

On sait qu'il y a une erreur, mais lorsqu'il y en a une, il y a en général un message qui donne des indications. C'est cela que l'on te demande.

Philippe