Discussion :

[cheikhoufia]

Bonjour je voudrais qu'à chaque fois que la colonne Etat de ma Tableau TABLE1 a pour valeur "Ok" qu'il mette la ligne correspondante en rouge

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
nb est un entier
gnCpt1=1
gnCpt2=TableOccurrence(TABLE1)
TANTQUE gnCpt1<=gnCpt2
	TableSelectPlus(MoiMême,gnCpt1)
	nb=0
	SI FEN_TABLE1.COL_EtatDA="Ok" ALORS
		nb=gnCpt1
		FEN_TABLE1..CouleurFond=RougeClair
	FIN
	TableSelectMoins(TABLE1,gnCpt1)
	gnCpt1=gnCpt1+1
FIN

[Nicolas_Jeanneau]

Bonjour,

il me semble que cela devrait marcher. Comme tu ne dis pas ce qui se passe c'est compliqué de savoir où t'aider.
Tu dois cependant faire attention à mettre un sinon pour prendre la couleur de fond par défaut.

Tu peux aussi utiliser la fonction "Pour toute ligne de " Table1 qui te permet de ne pas gérer de compteur ...

à bientôt,

Nicolas

[cheikhoufia]

j'ai modifié le code ainsi mais ce qui se passe c'est que c'est la couleur de fond du tableau qui se colorie en rouge, moi je voudrais mettre la ligne correspondant en rouge. Maintenant je pense que le probléme se trouve au niveau de l'indice de parcours que je n'arrive pas à déterminer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
POUR TOUTE LIGNE DE TABLE_DEMANDEAGREMENT
	SI TABLE_DEMANDEAGREMENT.COL_EtatDA="Envoyée" ALORS
		TABLE_DEMANDEAGREMENT..CouleurFond=RougeClair
	FIN
 
FIN

[cheikhoufia]

J'ai mis ce code et ça marche

n est un entier=TableOccurrence(TABLE_DEMANDEAGREMENT)
i est un entier
POUR i=1 A n
TableSelectPlus(TABLE_DEMANDEAGREMENT,i)
SI TABLE_DEMANDEAGREMENT.COL_EtatDA="Envoyée" ALORS
TABLE_DEMANDEAGREMENT[i]..CouleurFond=iRougeClair
SINON
TABLE_DEMANDEAGREMENT[i]..CouleurFond=iCouleurDéfaut
FIN
FIN


Merci!!!!!!!!!!!

[Hemgé]

Bonjour,

Dans le code que vous avez posté, vous pouvez supprimer l'instruction TableSelectPlus : puisque vous désignez la ligne avec son indice [i], elle ne doit pas être sélectionnée auparavant.

Retenez plutôt la suggestion de Nicolas_Jeanneau qui est plus efficace et se relit plus aisément.

Allez voir la doc - 1ère syntaxe et retenez que vous pouvez utiliser une variable indice qu'il ne faut même pas déclarer.

Le second code que vous aviez posté devient alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
POUR TOUTE LIGNE i DE TABLE_DEMANDEAGREMENT
   SI TABLE_DEMANDEAGREMENT[i].COL_EtatDA="Envoyée" ALORS
      TABLE_DEMANDEAGREMENT[i]..CouleurFond=RougeClair
   FIN	
FIN

Et retenez aussi la seconde syntaxe de Parcours des éléments sélectionnés, qui vous permettrait si vous maintenez votre TableSelectPlus de traiter sélectivement les lignes qui ont été sélectionnées.

Bon travail

Hemgé

[hpascal]

Bonjour

Il manque juste l'indice de la ligne en cours dans ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
POUR TOUTE LIGNE DE TABLE_DEMANDEAGREMENT
   SI TABLE_DEMANDEAGREMENT.COL_EtatDA = "Envoyée" ALORS
      TABLE_DEMANDEAGREMENT[TABLE_DEMANDEAGREMENT]..CouleurFond = RougeClair
   FIN
FIN

[tatayo]

Bonjour,
A mon avis le plus simple est de mettre le code (sans la boucle) dans la section "Affichage d'une ligne de la table".

Tatayo.

[hpascal]

A mon avis le plus simple est de mettre le code (sans la boucle) dans la section "Affichage d'une ligne de la table".

Entièrement d'accord avec toi

[cladoo]

Tatayo a raison

ça donne donc un truc comme ça (code à mettre dans 'Affichage d'une ligne de MATABLE')

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
SELON MATABLE.COL_Info[MATABLE]
	CAS 1 
		MATABLE[MATABLE]..CouleurFond = VertPastel
	CAS 2 
		MATABLE[MATABLE]..CouleurFond = CyanPastel
	CAS 3 
		MATABLE[MATABLE]..CouleurFond = RougePastel
	AUTRE CAS
		MATABLE[MATABLE]..CouleurFond = iCouleurDéfaut		
FIN