Discussion :

[apt]

Bonsoir à tous,

Sur une même base de données, j'aimerais appliquer déférents type de filtrage et cela selon la valeur choisie d'une case d'option.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub FiltreOption()
    Dim Crit As Range
    With Sheets("feuil2")
        .[H3] = .[H9] & .[H11]    '1er Critère Arrêt
        .[I3] = .[I9] & .[I11]    '2ème Critère "Arrêt
        .[J3] = .[J9] & .[J11]    '3ème Critère Dn"
        Set Crit = .Range("H2:J3")
        Crit(2, 3).Value = Replace(Crit(2, 3).Value, ",", ".")
 
        Select Case Sheets("Feuil").[E2]
        Case 1    'FIltre sur place
            ActionFiltre = xlFiltreInPlace
        Case 2    'Filtre sur une nouvelle feuille
            ActionFiltre = xlFiltreCopy
        Case 3    'Filtre dans une nouvelle feuille plus impression
            ActionFiltre = xlFiltreCopy
        End Select
 
        .Range("A2:E63").AdvancedFilter _
                Action:=ActionFiltre, _
                CriteriaRange:=[Crit], _
                CopyToRange:=.Range("J2:L2"), _
                Unique:=False
    End With
End Sub

Merci d’avance.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub FiltreOption()
Dim Crit As Range
Dim ActionFiltre As Byte
Dim Prnt As Boolean
 
With Sheets("BD")
    .[H3] = .[H9] & .[H11]                         '1er Critère Arrêt
    .[I3] = .[I9] & .[I11]                         '2ème Critère "Arrêt
    .[J3] = .[J9] & .[J11]                         '3ème Critère Dn"
    Set Crit = .Range("H2:J3")
    Crit(2, 3).Value = Replace(Crit(2, 3).Value, ",", ".")
 
    '--Type de filtrage selon la valeur de la case d'option sur la feuille
    Select Case Sheets("Acceuil").[E2]
        Case 1                                     'FIltre sur place
            ActionFiltre = 1
        Case 2                                     'Filtre dans une nouvelle feuille
            ActionFiltre = 2
        Case 3                                     'Filtre dans une nouvelle feuille plus impression
            ActionFiltre = 2
            Prnt = True
    End Select
 
    .Range("A2:E63").AdvancedFilter Action:=ActionFiltre, CriteriaRange:=[Crit], CopyToRange:=.Range("M1:Q1"), Unique:=False
    If Prnt Then .Range("M1").CurrentRegion.PrintOut
    Set Crit = Nothing
End With
End Sub

[apt]

Bonsoir mercatog,

Comme je devrais avant chaque filtrage savoir quelle case d'option a été sélectionner, j'ai codé une nouvelle procédure qui me rend le type de filtrage voulu, et j'ai déclaré les variables concernées comme public.

Mais voila, ces variables restent toujours vides après l'exécution de la procédure TypeFiltrage et le filtre déclenche une erreur (ActionFiltre=0) !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Option Explicit
Dim ActionFiltre As Byte
Dim Prnt As Boolean
Dim nOng As String
Sub TypeFiltrage()
'--Type de filtrage selon la valeur de la case d'option sur la feuille
    Select Case Sheets("Acceuil").[E2]
    Case 1                                     'FIltre sur place
        ActionFiltre = 1
        nOng = "BD"
    Case 2                                     'Filtre dans une nouvelle feuille
        ActionFiltre = 2
        nOng = "Feuil3"
    Case 3                                     'Filtre dans une nouvelle feuille plus impression
        ActionFiltre = 2
        Prnt = True
        nOng = "Feuil3"
    End Select
End Sub
Sub FiltreOption()
    Dim Crit As Range
 
    With Sheets("BD")
        'ActiveSheet.ShowAllData
        On Error Resume Next
        .ShowAllData
        '[M1].CurrentRegion.ClearContents
        Sheets("Feuil3").Range("A3:D100").ClearContents
        On Error GoTo 0
        .[H3] = .[H9] & .[H11]                         '1er Critère Arrêt
        .[I3] = .[I9] & .[I11]                         '2ème Critère "Arrêt
        .[J3] = .[J9] & .[J11]                         '3ème Critère Dn"
        Set Crit = .Range("H2:J3")
        Crit(2, 3).Value = Replace(Crit(2, 3).Value, ",", ".")
 
 
        .Range("A2:E63").AdvancedFilter Action:=ActionFiltre, CriteriaRange:=[Crit], CopyToRange:=Sheets("Feuil3").Range("A2:D2"), Unique:=False
        'If Prnt Then .Range("M1").CurrentRegion.PrintOut
        Sheets(nOng).Activate
    End With
 
    Set Crit = Nothing
End Sub

[mercatog]

Il faudra appeler la procédure TypeFiltrage au sein de FiltreOption

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Dim ActionFiltre As Byte
Dim Prnt As Boolean
Dim nOng As String
Sub TypeFiltrage()
 
'--Type de filtrage selon la valeur de la case d'option sur la feuille
Prnt = False
Select Case Sheets("Acceuil").[E2]
    Case 1                                         'FIltre sur place
        ActionFiltre = 1
        nOng = "BD"
    Case 2                                         'Filtre dans une nouvelle feuille
        ActionFiltre = 2
        nOng = "Feuil3"
    Case 3                                         'Filtre dans une nouvelle feuille plus impression
        ActionFiltre = 2
        Prnt = True
        nOng = "Feuil3"
End Select
End Sub
Sub FiltreOption()
Dim Crit As Range
 
With Sheets("BD")
    'ActiveSheet.ShowAllData
    On Error Resume Next
    .ShowAllData
    On Error GoTo 0
 
    .[H3] = .[H9] & .[H11]                         '1er Critère Arrêt
    .[I3] = .[I9] & .[I11]                         '2ème Critère "Arrêt
    .[J3] = .[J9] & .[J11]                         '3ème Critère Dn"
    Set Crit = .Range("H2:J3")
    Crit(2, 3).Value = Replace(Crit(2, 3).Value, ",", ".")
 
    TypeFiltrage ' ICI
 
    .Range("A2:E63").AdvancedFilter Action:=ActionFiltre, CriteriaRange:=[Crit], CopyToRange:=Sheets(nOng).Range("A2:E2"), Unique:=False
    If Prnt Then Sheets(nOng).Range("A2").CurrentRegion.PrintOut
    Sheets(nOng).Activate
End With
 
Set Crit = Nothing
End Sub

[apt]

Bonjour mercatog,

Il faudra appeler la procédure TypeFiltrage au sein de FiltreOption

C'est ce que j'ai fait dans un autre code adapté.

Seulement, l'erreur était que j'ai redéfinis à nouveau les valeurs publiques en privées dans la procédure FIltreOption

C'est pout cela, que les variables issues de la procédure TypeFiltrage s'effacent quand on retourne dans la procédure FiltreOption.

Merci mercatog.