Discussion :

[maxval18]

Bonjour,

J'ai un code qui marche bien mais j'aimerai lui apporter une petite modif.
Je découpe une chaine de caractères sur plusieurs colonne comme ceci

Quemper-Guézennec(22260) sa donne Quemper-Guézennec sur une colonne et 22260 sur une autre la colonne

Seul problème et que si une cellule est vide ou si une cellule contient une lettre comme "A, B, C ect.." sa beug?
Si quelqu'un a une idée.

je vous remercie d'avance.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub Découpe()
      Dim DLig As Long, Lig As Long
      ' Tableau des données séparées
     Dim sTab() As String
      With Sheets("Feuil1")
        ' Trouver la dernière ligne remplie de la colonne B
       DLig = .Range("B" & Rows.Count).End(xlUp).Row
 
        ' Pour chaque ligne en commençant par la 4ème
       For Lig = 4 To DLig
 
          ' Eclater la valeur en 2 à partir de la parenthèse
         sTab = Split(.Range("B" & Lig), "(")
          ' Inscrire les valeurs
         .Range("D" & Lig) = Trim(sTab(0))
          .Range("E" & Lig) = Left(sTab(1), Len(sTab(1)) - 1)
 
       ' Eclater la valeur en 2 à partir de la parenthèse
       sTab = Split(.Range("G" & Lig), "(")
      ' Inscrire les valeurs
       .Range("I" & Lig) = Trim(sTab(0))
         .Range("J" & Lig) = Left(sTab(1), Len(sTab(1)) - 1)
 
    Next Lig
      End With
 
 
    End Sub

Cordialement

Max

[mercatog]

Une autre approche, utiliser l'outil convertir d'excel avec "(" comme séparateur.

Dans l'exemple ici, les données de la colonne D sont converties en colonnes D et E

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Dim Rng As Range
 
Application.ScreenUpdating = False
'on définit notre plage de données
With Worksheets("Feuil1")
    Set Rng = .Range("B4:B" & .Cells(.Rows.Count, "B").End(xlUp).Row)
End With
'on désactive les alertes excel
Application.DisplayAlerts = False
'On convertit les données de la colonne B avec "(" comme séparateur, le résultat s'inscrira à partir de la colonne D
Rng.TextToColumns Destination:=Rng.Offset(0, 2)(1, 1), DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, Other:=True, OtherChar:="(", FieldInfo:=Array(Array(1, 1), Array(2, 1))
'on réactive les alertes excel
Application.DisplayAlerts = True
'on supprime la parenthèse fermante
Rng.Offset(0, 3).Replace ")", "", xlPart
Set Rng = Nothing

[maxval18]

Bonjour Mercatog

je te remercie super

Comment je fait pour les données de la colonne G qui sont a converties en colonnes I et J

Un grand merci d'avance

Max

[mercatog]

Pour ce cas on fait une procédure qui prend en paramètre la plage de données source

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Convertir(ByVal Rng As Range)
 
Application.DisplayAlerts = False
Rng.TextToColumns Destination:=Rng.Offset(0, 2)(1, 1), DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, Other:=True, OtherChar:="(", FieldInfo:=Array(Array(1, 1), Array(2, 1))
Application.DisplayAlerts = True
Rng.Offset(0, 3).Replace ")", "", xlPart
End Sub

Et pour son application aux colonnes B et G

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Test()
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    Convertir .Range("B4:B" & .Cells(.Rows.Count, "B").End(xlUp).Row)
    Convertir .Range("G4:G" & .Cells(.Rows.Count, "G").End(xlUp).Row)
End With
End Sub

Attention quand même, si une colonne B et G sont vides, il y aura une erreur (Qu'on peut gérer facilement avec une ligne de code supplémentaire)

[maxval18]

Re,

Sa marche super bien

mais tu me dit:

Attention quand même, si une colonne B et G sont vides, il y aura une erreur (Qu'on peut gérer facilement avec une ligne de code supplémentaire)

Comment?

Merci pour tous et bonne journée

Max

[mercatog]

Il suffit de tester sir la dernière ligne remplie est supérieur ou égale à 4 (puisque tu commence à la ligne 4)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Convertir(ByVal Rng As Range)
 
Application.DisplayAlerts = False
If Rng.Row >= 4 Then
    Rng.TextToColumns Destination:=Rng.Offset(0, 2)(1, 1), DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, Other:=True, OtherChar:="(", FieldInfo:=Array(Array(1, 1), Array(2, 1))
    Application.DisplayAlerts = True
    Rng.Offset(0, 3).Replace ")", "", xlPart
End If
End Sub