Discussion :

[sdispro]

Salut le forum,

Je fais fasse à un problème auquel je ne trouve ni réponse dans mes maigres compétences ni dans les forums.

J'ai un userform avec un contrôle mulipage.
J'ai 5 pages, nommées page1, page2, page3 ...
J'ai des onglets sur le classeur excel portant les mêmes noms.
Je souhaitererai que lorsque je change de page ("multipage de mon userform), l'onglet du classeur (du même nom) soit selectionner automatiquement et cela sans bouton.

J'ai essayé de trifouiller dans Private Sub MultiPage1_Change() mais sans aucun résultats.

En espérant trouver de l'aide, je vous souhaite une bonne journée.

[BlueMonkey]

Bonjour,

Dans le code de la UserForm contenant le contrôle multipage, ajouter le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private ActivetabName As String
 
Private Sub MultiPage1_Change()
    If ActivetabName <> MultiPage1.SelectedItem.Caption Then
        ActivetabName = MultiPage1.SelectedItem.Caption
        On Error Resume Next
        ThisWorkbook.Worksheets(ActivetabName).Activate
    End If
End Sub

S'il faut interagir avec le classeur tout en gardant la UserForm visible,
il faudra l'afficher de façon non modale : UserForm1.Show(False).

[sdispro]

Merci beaucoup,

Cela repond totalement a mes besoins.
Affaire résolue

[sdispro]

Re bonjour,

Je voudrais adapter ce code pour aller plus loin.

Lorsque je clique sur le nom page1, cela m'ouvre le fichier page1.xls, si je change de page cela le ferme, est ce possible.

Merci par avance

[HopPopPop]

Bonjour à tous,

Dans la continuité de BlueMonkey :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Dim ActivetabName As String
Dim ExActivetabName As String
Dim EvitSub As Boolean
 
Private Sub MultiPage1_Change()
    If EvitSub Then Exit Sub
    ExActivetabName = ActivetabName
    If ActivetabName <> MultiPage1.SelectedItem.Caption Then
        ActivetabName = MultiPage1.SelectedItem.Caption
        On Error Resume Next
        ThisWorkbook.Worksheets(ActivetabName).Visible = True
        ThisWorkbook.Worksheets(ActivetabName).Activate
        ThisWorkbook.Worksheets(ExActivetabName).Visible = False
    End If
End Sub
 
Private Sub UserForm_Activate()
 
EvitSub = True
 
ActivetabName = ThisWorkbook.ActiveSheet.Name
MultiPage1.Value = Right(ActiveSheet.Name, 1) - 1
Dim i As Byte
For i = 1 To 5
    If Sheets("Page" & i).Name <> ActiveSheet.Name Then Sheets("Page" & i).Visible = False
Next
 
EvitSub = False
End Sub

A l'affichage du formulaire, la feuille active affichera l'onglet du Multipage concerné et les autres feuilles seront masquées.
Lors d'une sélection d'un autre onglet sur le multipage, la feuille concernée s'affichera et la précédente sera masquée.

Cordialement.