Discussion :

[Julia`]

Bonjour

Avant toute chose, sachez que .... je n'y connais RIEN en vbs lol (sinon je viendrai pas pleurer ici )

Bon je suis certaine qu'il y a une bonne ame sur ce forum pour me dépatouiller de ce soucis!

J'explique, il me faudrait un script, à l'ouverture de session qui dit fait ceci (bref j'ai besoin d'une traduction ):



Lecture de l'ip de la connexion internet
si l'ip est IP-A alors tu mets l'imprimante A par défaut
si l'ip est IP-B alors tu mets l'imprimante B par défaut


Je sais, vous allez me dire "mais sur 7, tu peux en fonction du réseau sur lequel tu te connectes choisir ton imprimante par défaut"..... oui mais non , car les 2 réseaux (même entreprise, mais pas même connexion internet, passe par vpn) portent le même nom... (ben oui sinon... c'est pas drôle)!!

Merci beaucoup

[cubitus91]

Hello Julia,

Bonjour
Avant toute chose, sachez que .... je n'y connais RIEN en vbs lol (sinon je viendrai pas pleurer ici )

Il n'est jamais trop tard pour commencer à apprendre

Sinon pour ton script, voila :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Select Case GetAdressip
    Case "AdressA" 
    WScript.Echo "Add Printer A"
    MapNetworkPrinter "UNC Path imprimante A"
    Case "AdressB"  
    WScript.Echo "Add Printer B"
    MapNetworkPrinter "UNC Path imprimante B"
    Case "AdressC"  
    WScript.Echo "Add Printer C"
    MapNetworkPrinter "UNC Path imprimante C"
    Case Else 
    WScript.Echo "Réseau non reconnu"
 
End Select
 
Private Function GetAdressip()
'local var
Dim objWMIService,ColNetworks,NetworkItem
Dim strIPAddress
Set objWMIService = GetObject("winmgmts:\\.\root\CIMV2") 
Set ColNetworks = objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration where IPEnabled = true",,48) 
For Each NetworkItem in ColNetworks 
 strIPAddress = NetworkItem.IPAddress(0)
Next 
Set objWMIService = Nothing
Set ColNetworks = Nothing
GetAdressip =  strIPAddress
End Function 
 
Private Sub MapNetworkPrinter(UNCPrinter)
'local var 
Dim ObjNetwork
Set ObjNetwork = CreateObject("WScript.Network") 
ObjNetwork.AddWindowsPrinterConnection UNCPrinter
Set ObjNetwork = Nothing 
End Sub

Par contre ca me parait bizard que tu prennes l'adresses ip, comme référence. Car cela veut dire que tu dois faire dans ton script autant de cas que tu as d'imprimantes.
Ne peux tu pas trouver un facteur commun.
Cordialement