1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
| [Setup]
AppName=Mesure 2004
AppVerName=Mesure 2004 1.0
PrivilegesRequired=admin
DefaultDirName={pf}\Mesure2004
DefaultGroupName=Mesure 2004
OutputBaseFilename=Mesure2004Setup
MinVersion=4.1.2222,5.0.2195
AppCopyright=Copyright© 2004 AIM sarl
LicenseFile=C:\Applications VB6\licence.txt
AppID={{83C4FB41-8B60-4CA5-AFF4-C0C2C8305624}}
UninstallDisplayIcon={app}\Mesure2004.exe
WizardImageFile=C:\Program Files\Inno Setup 5\WizModernImage-IS.bmp
WizardSmallImageFile=C:\Program Files\Inno Setup 5\WizModernSmallImage-IS.bmp
SourceDir=C:\Applications VB6\Banc MICHELIN\IK220
OutputDir=C:\Applications VB6\Banc MICHELIN\IK220\Package
[Languages]
Name: en; MessagesFile: compiler:Default.isl
Name: fr; MessagesFile: compiler:Languages\French.isl
[Tasks]
Name: DCOM98; Description: D&COM 1.3 pour Windows 98; GroupDescription: Compléments:; Flags: checkedonce restart; MinVersion: 4.1.1998,0; OnlyBelowVersion: 4.9,0
Name: MDAC; Description: Microsoft Data &Access Components; GroupDescription: Compléments:; Flags: checkedonce restart; MinVersion: 4.0,4.0; OnlyBelowVersion: 0,5.0
Name: desktopicon; Description: Créer une icône sur le &bureau; GroupDescription: Icônes:; Flags: checkedonce
Name: quicklaunchicon; Description: Créer une icône de &démarrage rapide; GroupDescription: Icônes:; Flags: unchecked
[Files]
; [VB system files]
Source: c:\Redist\VB_Runtime\stdole2.tlb; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regtypelib
Source: c:\Redist\VB_Runtime\msvbvm60.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: c:\Redist\VB_Runtime\oleaut32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: c:\Redist\VB_Runtime\olepro32.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: c:\Redist\VB_Runtime\asycfilt.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile
Source: c:\Redist\VB_Runtime\comcat.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile regserver
Source: c:\Redist\VB_Runtime\Vb6fr.dll; DestDir: {sys}; Flags: restartreplace uninsneveruninstall promptifolder sharedfile
; [Setup1 Files]
Source: c:\Redist\MDAC_TYP.EXE; DestDir: {app}; Flags: promptifolder deleteafterinstall nocompression; Tasks: MDAC
Source: c:\Redist\DCom\dcom98.EXE; DestDir: {app}; Flags: promptifolder deleteafterinstall nocompression; Tasks: DCOM98
Source: C:\winnt\system32\CMCT3FR.DLL; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\COMCT332.OCX; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\DATGDFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\STDFTFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\Msstdfmt.dll; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\MSDATGRD.OCX; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\MSHFGFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\MSHFLXGD.OCX; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\CMDLGFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\Comdlg32.ocx; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\MFC40LOC.DLL; DestDir: {sys}; Flags: restartreplace uninsneveruninstall sharedfile allowunsafefiles
Source: C:\winnt\system32\MFC40.DLL; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\Threed32.ocx; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\TABCTFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\Tabctl32.ocx; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\MSCMCFR.DLL; DestDir: {sys}; Flags: promptifolder sharedfile allowunsafefiles
Source: C:\winnt\system32\Mscomctl.ocx; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
Source: C:\winnt\system32\MSBIND.DLL; DestDir: {sys}; Flags: promptifolder regserver sharedfile allowunsafefiles
; [Application Files]
Source: IK220Dll.Dll; DestDir: {sys}; Flags: promptifolder confirmoverwrite uninsneveruninstall
Source: Mesure2004.exe; DestDir: {app}; Flags: promptifolder
Source: rsE.dat; DestDir: {app}; Flags: promptifolder onlyifdoesntexist
Source: rsA.dat; DestDir: {app}; Flags: promptifolder onlyifdoesntexist
Source: IK220.ini; DestDir: {app}; Flags: onlyifdoesntexist
Source: Mesure2004ini.txt; DestName: Mesure2004.ini; DestDir: {app}; Flags: onlyifdoesntexist
Source: Pics\*.*; DestDir: {app}\Pics
Source: HTML Help\Mesure2004.chm; DestDir: {app}
Source: ReadMe.txt; DestDir: {app}; Flags: isreadme
Source: C:\Applications VB6\licence.txt; DestDir: {app}
; [Fonts]
Source: C:\winnt\Fonts\Digirtu_.ttf; DestDir: {fonts}; FontInstall: Digital Readout Thick Upright; Flags: onlyifdoesntexist uninsneveruninstall
[Icons]
Name: {group}\Mesure2004; Filename: {app}\Mesure2004.exe; WorkingDir: {app}
Name: {group}\Licence; Filename: {app}\licence.txt
Name: {group}\ReadMe; Filename: {app}\ReadMe.txt
Name: {group}\Uninstall Mesure2004; Filename: {uninstallexe}
Name: {userdesktop}\Mesure2004; Filename: {app}\Mesure2004.exe; WorkingDir: {app}; Tasks: desktopicon
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\Mesure2004; Filename: {app}\Mesure2004.exe; WorkingDir: {app}; Tasks: quicklaunchicon
[_ISTool]
UseAbsolutePaths=true
EnableISX=false
[Dirs]
Name: {app}; Flags: uninsalwaysuninstall
Name: {app}\Hist; Flags: uninsalwaysuninstall
Name: {app}\Local; Flags: uninsalwaysuninstall
Name: {app}\Pics; Flags: uninsalwaysuninstall
[INI]
Filename: {app}\Mesure2004.ini; Section: Dir; Key: DirFichIn; String: {userdocs}; Flags: uninsdeletesection createkeyifdoesntexist
Filename: {app}\Mesure2004.ini; Section: Dir; Key: DirFichOut; String: {userdocs}; Flags: uninsdeletesection createkeyifdoesntexist
Filename: {app}\Mesure2004.ini; Section: Dir; Key: DirFichLoc; String: {app}\Local; Flags: uninsdeletesection createkeyifdoesntexist
Filename: {app}\Mesure2004.ini; Section: Dir; Key: DirFichHist; String: {app}\Hist; Flags: uninsdeletesection createkeyifdoesntexist
Filename: {app}\Mesure2004.ini; Section: Dir; Key: DirToolsCall; String: {pf}\ToolsCall; Flags: uninsdeletesection createkeyifdoesntexist
[Registry]
; Delay MDAC installation on Win95 machines
;MDAC 2.0+
Root: HKCU; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce; ValueType: string; ValueName: MDAC_Setup; ValueData: """{%TEMP}\mdac_typ.exe"" /Q /C:""setup /QT"""; MinVersion: 4.0,0; Tasks: MDAC
; Clés Registre Programme
Root: HKCU; Subkey: Software\VB and VBA Program Settings\Mesure2004; Flags: uninsdeletekey
Root: HKCU; Subkey: Software\VB and VBA Program Settings\Mesure2004\Setup; ValueType: string; ValueName: LicenseName; ValueData: {code:GetUserCompany}
Root: HKCU; Subkey: Software\VB and VBA Program Settings\Mesure2004\Setup; ValueType: string; ValueName: LicenseNumber; ValueData: xx-xx-xxx
[Run]
; START DCOM
Filename: {app}\dcom98.exe; Parameters: /r:n /q:u; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: DCOM98; MinVersion: 4.1,0
; START MDAC 2.0+
Filename: {app}\mdac_typ.exe; Parameters: "/Q /C:""setup /QNT"""; WorkingDir: {tmp}; Flags: skipifdoesntexist; Tasks: MDAC; MinVersion: 4.1,0
[ Code]
var { Variables Globales }
UserPage: TInputQueryWizardPage;
{ Procédures d'évenements }
procedure URLLabelOnClick(Sender: TObject);
var
ErrorCode: Integer;
begin
ShellExec('open', 'http://www.aim69.fr', '', '', SW_SHOWNORMAL, ewNoWait, ErrorCode);
end;
{ INITIALISATION }
procedure InitializeWizard;
var
URLLabel: TNewStaticText;
begin
{ Create the pages }
UserPage := CreateInputQueryPage(wpLicense,
'Informations Personnelles', 'Qui êtes-vous?',
'Entrer votre nom et celui de votre société, et cliquer sur Suivant.');
UserPage.Add('Nom:', False);
UserPage.Add('Société:', False);
{ Set default values, using settings that were stored last time if possible }
UserPage.Values[0] := GetPreviousData('Nom', ExpandConstant('{sysuserinfoname}'));
UserPage.Values[1] := GetPreviousData('Société', ExpandConstant('{sysuserinfoorg}'));
{ Créer et positionner un label lien hypertexte personnalisé }
URLLabel := TNewStaticText.Create(WizardForm);
URLLabel.Caption := 'www.aim69.fr';
URLLabel.Cursor := crHand;
URLLabel.OnClick := @URLLabelOnClick;
URLLabel.Parent := WizardForm;
{ Alter Font *after* setting Parent so the correct defaults are inherited first }
URLLabel.Font.Style := URLLabel.Font.Style + [fsUnderline];
URLLabel.Font.Color := clBlue;
URLLabel.Top := WizardForm.ClientHeight - URLLabel.Height - 15;
URLLabel.Left := ScaleX(20);
end;
procedure RegisterPreviousData(PreviousDataKey: Integer);
var
UsageMode: String;
begin
{ Store the settings so we can restore them next time }
SetPreviousData(PreviousDataKey, 'Nom', UserPage.Values[0]);
SetPreviousData(PreviousDataKey, 'Société', UserPage.Values[1]);
end;
function NextButtonClick(CurPageID: Integer): Boolean;
var
I: Integer;
begin
{ Valider certaines pages avant d'autoriser à continuer }
if CurPageID = UserPage.ID then
begin
if UserPage.Values[1] = '' then
begin
MsgBox('Vous devez entrer un nom pour votre société.', mbError, MB_OK);
Result := False;
end
else
Result := True;
end
else
Result := True;
end;
function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo,
MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
var
S: String;
begin
{ Remplir le recapitulatif (Ready Memo) avec les informations personnalisées }
S := '';
S := S + 'Informations Personnelles:' + NewLine;
if UserPage.Values[0] <> '' then
S := S + Space + UserPage.Values[0] + NewLine;
if UserPage.Values[1] <> '' then
S := S + Space + UserPage.Values[1] + NewLine;
S := S + NewLine;
{ Ajouter les informations standards au recapitulatif }
if MemoUserInfoInfo <> '' then S := S + MemoUserInfoInfo + NewLine + NewLine;
if MemoDirInfo <> ''then S := S + MemoDirInfo + NewLine + NewLine;
if MemoTypeInfo <> ''then S := S + MemoTypeInfo + NewLine + NewLine;
if MemoComponentsInfo <> ''then S := S + MemoComponentsInfo + NewLine + NewLine;
if MemoGroupInfo <> ''then S := S + MemoGroupInfo + NewLine + NewLine;
if MemoTasksInfo <> ''then S := S + MemoTasksInfo;
Result := S;
end;
function GetUserName(Param: String): String;
begin
Result := UserPage.Values[0]
end;
function GetUserCompany(Param: String): String;
begin
Result := UserPage.Values[1]
end;
{END SETUP Code} |
[VB6]Empaquetage : fichiers périmés
:
....Vois pas (une fée, peut-être ?)
Répondre avec citation
Partager