Discussion :

[Arnoym]

Bonsoir à toutes et tous,

j'ai beau fouiller partout ici et ailleurs sur le web et je ne trouve pas réponse à ma question alors je fais appel à vous.

J'utilise actuellement une macro pour l'enregistrement de fichier excel.
Avec cette macro, l'utilisateur se voit proposé un nom de fichier par défaut et il peut si il le souhaite, modifier manuellement le repertoire de destination ou à défaut, valider celui qui est également proposé.

voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub CommandButton1_Click
Dim nom
   nom = Application.GetSaveAsFilename(InitialFileName:=Range("A1").Value)
   ActiveWorkbook.SaveAs Filename:=nom, FileFormat:=xlExcel8
End sub

J'aimerais avoir le même fonctionnement avec la fonction "enregistrer sous/PDF ou XPS" pour exploiter la fonction PDF.

Mon soucis est qu'en utilisant le code ci-dessous, la boite de dialogue n'apparait même pas et il est impossible de sélectionner le répertoire de destination ou de changer le nom du fichier à enregistrer.

Le seul code que j'ai trouvé (grace à l'éditeur de macro) .. mais qui ne me convient pas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Macro8()
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        "Nom_du_fichier.pdf", Quality:= _
        xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
End Sub

J'espère être assez clair et je vous remercie par avance pour votre aide,

Slts

[kiki29]

Salut, tu aurais pu obtenir ces codes via l'aide en ligne [F1] sur GetSaveAsFilename

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
 
Sub Tst1()
Dim sNom As Variant
    ChDir ThisWorkbook.Path
    sNom = Application.GetSaveAsFilename(InitialFileName:="Essai", _
                                         fileFilter:="Excel (*.xls), *.xls")
    If sNom = False Then Exit Sub
    ActiveWorkbook.SaveAs Filename:=sNom, FileFormat:=xlExcel8
End Sub
 
Sub Tst2()
Dim sNom As Variant
    ChDir ThisWorkbook.Path
    sNom = Application.GetSaveAsFilename(InitialFileName:="Essai", _
                                         fileFilter:="PDF (*.pdf), *.pdf")
    If sNom = False Then Exit Sub
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
                                    Filename:=sNom, _
                                    Quality:=xlQualityStandard, _
                                    IncludeDocProperties:=True, _
                                    IgnorePrintAreas:=False, _
                                    OpenAfterPublish:=False
End Sub

[Arnoym]

Un grand Merci Kiki29 !!!!

Très sincèrement j'ai passé la soirée à chercher la combine mais je n'en pouvais plus à force.
Je suis un noob en macro / excel mais j'arrive à bidouiller et à trouver ce que je veux en général mais là ...

Tu m'enlèves une sacrée épine du pied.

Encore merci.