Fermeture d'une fenêtre IE automatique

**offrock** · 18/04/2012, 11h37

Bonjour à tous !

J'ai en ma possession un script vbs qui marche très bien, un script (pour moi très compliqué avec plein de variables pour monter des lecteurs réseaux, je précise que ce n'est pas moi qui l'ai conçu). Le script s'éxécute dans une fenêtre internet explorer, l'utilisateur doit cependant l'a fermé, j'aimerai mettre un timer dans le script pour qu'elle se ferme au bout de 3 secondes (exemple) sans intervention.

J'ai vu une discussion portant sur ce sujet mais je suis archi débutant et comprends pas grand chose pour l'instant

Merci de votre aide en tout cas

La partie fenetre IE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
on error resume next
 
    Dim objExplorer 'as Object
    Set objExplorer = CreateObject("InternetExplorer.Application")
    objExplorer.Navigate "about:blank"
    objExplorer.ToolBar = 0
    objExplorer.StatusBar = 0
    objExplorer.Width = 410
    objExplorer.Height = 400
    objExplorer.Left = 50
    objExplorer.Top = 50
    Do While (objExplorer.Busy)
        Wscript.Sleep 200
    Loop
    objExplorer.Visible = 1
    objExplorer.Document.WriteLn "<html><head><title>Ouverture de session en cours...</title></head>"
    objExplorer.Document.WriteLn "<body bgcolor=""#000066""><align=""center""><br/>"
    objExplorer.Document.WriteLn "<div><font size=""2"" face=""Arial"" color=""white"">"
    objExplorer.Document.WriteLn "Connexion au domaine en cours...<br/>"

**hackoofr** · 18/04/2012, 20h17

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim objExplorer 
    Set objExplorer = CreateObject("InternetExplorer.Application")
    objExplorer.Navigate "about:blank"
    objExplorer.ToolBar = 0
    objExplorer.StatusBar = 0
    objExplorer.Width = 410
    objExplorer.Height = 400
    objExplorer.Left = 50
    objExplorer.Top = 50
    Do While (objExplorer.Busy)
        Wscript.Sleep 200
    Loop
    objExplorer.Visible = 1
    objExplorer.Document.WriteLn "<html><head><title>Ouverture de session en cours...</title></head>"
    objExplorer.Document.WriteLn "<body bgcolor=""#000066""><align=""center""><br/>"
    objExplorer.Document.WriteLn "<div><font size=""2"" face=""Arial"" color=""white"">"
    objExplorer.Document.WriteLn "Connexion au domaine en cours...<br/>"
	wscript.sleep 3000 ' pause de 3000 millisecondes=3 secondes
	objExplorer.quit
	set objExplorer = Nothing
	wscript.quit

**hackoofr** · 18/04/2012, 23h28

Voila une autre version à ma sauce

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Set colItems = GetObject("winmgmts:root\cimv2").ExecQuery("Select ScreenHeight, ScreenWidth from Win32_DesktopMonitor Where ScreenHeight Is Not Null And ScreenWidth Is Not Null") 
    For Each objItem in colItems 
        intHorizontal = objItem.ScreenWidth
        intVertical = objItem.ScreenHeight
    Next 
	Dim objExplorer 
    Set objExplorer = CreateObject("InternetExplorer.Application")
	objExplorer.Offline = True
    objExplorer.Navigate "about:blank"
    objExplorer.ToolBar = 0
    objExplorer.StatusBar = 0
    objExplorer.Left = (intHorizontal-300) / 2
    objExplorer.Top = (intVertical-300) / 2
    objExplorer.StatusBar = 0
    objExplorer.Width = 350
    objExplorer.Height = 150
    objExplorer.Visible = 1   
    objExplorer.Resizable = 0	
    objExplorer.MenuBar = 0
    objExplorer.Document.Title = "Ouverture de session en cours......."
    Do While (objExplorer.Busy)
        Wscript.Sleep 200
    Loop
   Dim strHTML : strHTML = "<html><head><center></head>"
    strHTML = strHTML & "<marquee BEHAVIOR='alternate'><B><font size='2' face='Arial' color='white'>"
    strHTML = strHTML & "Connexion au domaine en cours.....</marquee></B></body>"
	objExplorer.Document.Body.InnerHTML = strHTML
	objExplorer.Document.Body.Style.overflow = "auto"
	objExplorer.Document.body.style.backgroundcolor="blue"
	wscript.sleep 10000
	objExplorer.quit
	set objExplorer = Nothing
	wscript.quit

Fermeture d'une fenêtre IE automatique

VBScript

Vue hybride

Discussions similaires

Partager

Partager