Discussion :

[gbbtt]

Bonjour à tous,

Je débute dans l'utilisation de VBA pour Excel et des macros et j'ai d'ores et déjà quelque chose qui me semble complexe à réaliser.

Je souhaite qu'à l'ouverture de mon fichier automatiquement le premier onglet se remplisse de cases à cocher correspondants chacune à un fichier Excel annexes.
En pratique je souhaite que le fichier effectue une recherche de tous les classeurs commençant par "blabla" dans le dossier toto et crée la case à cocher correspondante.

Est-ce que cela vous parait faisable?
Si oui pourriez vous m'orienter sur les techniques à utiliser car je suis un peu perdu!

Merci d'avance

gbbtt

[Jean-Philippe André]

salut,

oui c'est tout à fait faisable. En procédant par étape, tu pourras le faire. Les pistes pour l'instant :
- exécution à l'ouverture du fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Workbook_Open()
'code à l'ouverture
End Sub

- parcours des fichiers d'un répertoire
http://access.developpez.com/faq/?pa...ep#contenu_rep

[Daniel.C]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Workbook_Open()
    Dim Fich As String, Ctr As Long
    With Sheets(1)
        'boucle sur les fichiersFich = Dir("C:\toto\blabla*.xls")
        Do While Fich <> ""
            'on va en mettre toutes les deux cellules
            Ctr = Ctr + 2
            'Création de la case à cocher (largeur 100, hauteur 20, à 10 points du bord)
            Set cb = .CheckBoxes.Add(10, .Cells(Ctr, 1).Top, 100, 20)
                'l'étiquette est le nom du fichier
                cb.Caption = Fich
                'la valeur est vide
                cb.Value = xlOff
                'la cellule liée est en colonne C
                cb.LinkedCell = .Cells(Ctr, 3)
            Fich = Dir
        Loop
    End With
End Sub

[gbbtt]

Merci pour les réponses Daniel et jpcheck.

J'avais effectivement trouvé la fonction Workbook_Open mais la suite se compliquait je m'étais embarqué dans beaucoup trop compliqué!

J'avais deux petites questions:

- dans un premier temps je dois supprimer l'intégralité des objets de la page car si je laisse comme ca, à la réouverture si j'ai supprimer ou ajouter des fichiers les cases à cocher s'écrivent par dessus les précédentes.
Je vois bien comment effacer les données (worksheet clear mais ça fonctionne pas pour les objets)

- A quoi correspond la cellule liée?

Merci encore pour votre aide


Edit: J'ai trouvé comment supprimer les objets de la feuille. J'ai cependant un autre souci, la routine ne se lance pas au moment de l'ouverture. Je suis obligé de la lancer manuellement alors que lors de tests précédent cela fonctionnait. C'est peut être (surement?) dû au fait que je doive cliquer sur autoriser les macros au moment de l'ouverture non?

[Daniel.C]

J'ai ajouté la suppression des checkboxes avant recréation. Elle fonctionne correctement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub Workbook_Open()
    Dim Fich As String, Ctr As Long, Sh As Shape
    With Sheets(1)
        'suppression des checkboxes
        On Error Resume Next
        For Each Sh In .Shapes
            If Sh.FormControlType = xlCheckBox Then
                Sh.Delete
            End If
        Next
        On Error GoTo 0
        'boucle sur les fichiers
        'Fich = Dir("C:\toto\blabla*.xls")
        Fich = Dir("C:\Users\Daniel\Documents\Donnees\Daniel\*.xls")
        Do While Fich <> ""
            'on va en mettre toutes les deux cellules
            Ctr = Ctr + 2
            'Création de la case à cocher (largeur 100, hauteur 20, à 10 points du bord)
            Set cb = .CheckBoxes.Add(10, .Cells(Ctr, 1).Top, 100, 20)
                'l'étiquette est le nom du fichier
                cb.Caption = Fich
                'la valeur est vide
                cb.Value = xlOff
                'la cellule liée est en colonne C
                cb.LinkedCell = .Cells(Ctr, 3).Address
            Fich = Dir
        Loop
    End With
End Sub

La cellule liée contient l'état du checkbox : VRAI si le checkbox est coché, FAUX dans le cas contraire. Elle n'est pas obligatoirement renseignée, mais permet parfois d'éviter du code en se servant de sa valeur pour tester l'état du checkbox dans une formule.

[gbbtt]

Merci beaucoup Daniel

C'est ce qu'il me semblait pour la cellule liée et je vais effectivement en avoir besoin pour la suite de mon travail.

Reste le problème du lancement de Workbook_Open mais je crois que je pourrais pas passer outre le message d'activation des macros qui semble bloquer la fonction.
S'il y a une solution je suis preneur, sinon tant pis je passe par un bouton c'est pas bien grave!

gbbtt