Discussion :

[louqui]

Bonjour à tous,

petit problème tout bête sans solution pour moi, dans une colonne j'ai des chiffres ainsi que des lettres qui sont variables, j'aimerai effacer tout le texte de cette colonne pour ne garder que les chiffres est ce possible?

Merci pour vos futures réponses

[casefayere]

Bonsoir,
Attention, ce code risque d'être long si tu as beaucoup de données, si c'est le cas il faudra passer par une variable tableau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Sub MACRO3()
 
Dim LastLig As Long, i As Long
'exemple en colonne D
LastLig = Range("D" & Rows.Count).End(xlUp).Row
For i = 2 To LastLig 'les données commencent en D2
 If IsNumeric(Range("D" & i)) = False Then
  Range("D" & i).ClearContents 'pour effacer la valeur
  'ou
  Range("D" & i).Clear 'pour effacer tout (y compris les formats)
  'ou
  Range("D" & i).Delete Shift:=xlUp 'pour supprimer la cellule et decaler les cellules vers le haut
 End If
Next i
 
End Sub

[louqui]

Merci pour cette réponse rapide. La macro proposée efface tout la cellule je pense qu'il doit prendre mes chiffres pour du texte alors? Dans la cellule c'est sous cette forme : 00701186 NOM

[casefayere]

Donc je n'ai pas compris ou tu t'es mal expliqué, tu as du texte et des chiffres au sein d'une même cellule, le code est donc à revoir mais ce soir, je fatigue, d'ici demain tu auras certainement la solution proposée par moi-même ou un autre membre.

Bonne nuit et bon courage

[mercatog]

Une petite fonction utilisant les expressions régulières

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Function EffaceLettres(ByVal Str As String) As String
Dim Rg As Object
 
If Len(Str) > 0 Then
    Set Rg = CreateObject("VBScript.RegExp")
    With Rg
        .Pattern = "\D"
        .Global = True
        Str = .Replace(Str, "")
    End With
    Set Rg = Nothing
    EffaceLettres = Str
End If
End Function

Qu'on peut utiliser sur la plage E1:E100 de Feuil1 comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test()
Dim Plage As Range, c As Range
 
Application.ScreenUpdating = False
Set Plage = Worksheets("Feuil1").Range("E1:E100")    'à adapter
Plage.NumberFormat = "@"
For Each c In Plage
    c.Value = EffaceLettres(c.Value)
Next c
Set Plage = Nothing
End Sub

Ci-après lien pour un précieux tutoriel de Caféine http://cafeine.developpez.com/access/tutoriel/regexp/

[casefayere]

Bonsoir mercatog,

comme je ne suis toujours pas couché, je pensais proposer un code dans ce style à louqui, à condition que ses cellules se présentent comme il le montre, soit : une suite de chiffres, un espace et du texte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
Public Sub MACRO3()
 
Dim LastLig As Long, i As Long, plage As Range, tablo()
Dim x() As String
'exemple en colonne D
LastLig = Range("D" & Rows.Count).End(xlUp).Row
ReDim tablo(1 To LastLig - 1)
Set plage = Range("D2:D" & LastLig)
For i = 2 To LastLig 'les données commencent en D2
  x = Split(Range("D" & i), " ")
  tablo(i - 1) = x(0)
Next i
plage = WorksheetFunction.Transpose(tablo)
End Sub

mais à savoir si ses cellules sont comme indiqué ci-dessus

bonne nuit

[louqui]

Toujours aussi efficace le forum! N'était pas encore couché moi non plus j'ai essayé la seconde proposition et ça a parfaitement fonctionné un grand merci à tous les deux!

[mercatog]

Bonsoir casefayere
Si les données sont comme tu dis

à condition que ses cellules se présentent comme il le montre, soit : une suite de chiffres, un espace et du texte

En une ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil1").Range("D:D").Replace " *", "", xlPart

[casefayere]

Bonsoir mercatog,
sans être publivore, j'ai envie de dire : << Je l'aurai un jour, je l'aurai >>
Encore chapeau ! pour ton esprit pratique, mais après test sur 15000 lignes, ma méthode est plus rapide (à l'exécution) apparemment, encore faut-il manipuler autant de lignes, 0,5 secondes contre 4,4 secondes.

Bonne soirée

[patricktoulon]

bonjour

bien que les codes de mercatog et case casefayere soient parfaits

si les valeurs dans les cellules sont bien une série de chiffre suivis d'un espace
et de lettre
il y avait une solution encore plus simple

avec le "split"

exemple pour supprimer toute les lettre dans les cellule a1 a a200

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub supprime_toute_lettre()
For Each cel In Range("a1:a200").Cells
If cel <> "" Then cel.Value = Split(cel.Value, " ")(0)
Next
End Sub

au plaisir

[mercatog]

Bonsoir
Une remarque, quand le séparateur est un espace, le 2ème paramètre se Split peut être omis

(Déclares tes variables et indente tes codes Patrick, il est temps)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub supprime_toute_lettre()
Dim Cel As Range
 
For Each Cel In Range("A1:A200").Cells
    If Cel <> "" Then Cel.Value = Split(Cel.Value)(0)
Next
End Sub

[patricktoulon]

bonjour mercatog
quand tu recopie mon code pour me faire des remarques essaie au moins de le copier en entier

Split(Cel.Value)(0)

????????

si il y a un separateur de plus pour les milliers dans ce cas la
une simple condition sur le tableau fera l'affaire

exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Sub supprime_toute_lettre()
Dim Cel As Range
dim tableau as variant
  For Each Cel In Range("A1:A200").Cells
   if Cel <> "" Then 
    tableau= Split(Cel.Value," ")
     if tableau=2 then Cel.Value = Split(Cel.Value," ")(1)
     if tableau=1 then Cel.Value = Split(Cel.Value," ")(0)
 
  end if 
 Next
End Sub

et indenté en plus

au plaisir

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Split(Cel.Value)(0)

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Split(Cel.Value," ")(0)

Ce sont 2 écritures identiques. C'était ma remarque qui t'as irrité. Relis là doucement.

Fais un F1 sur split, tu comprendras sans mes remarques.

[patricktoulon]

bonjour mercatog

je viens de faire l'essai sans la presision et ca ne fonctionne pas chez moi

ca me dis qu'il manque des arguments

mais de toute facon a fin d'eviter toute ambiguité je prefaire mettre les arguments on sait jamais
je vais regarder ca de plus pret ainsi que le "remp"dont tu a parlé dans mon dernier post

mais pour aujourdhui je ne suis pas chez moi et je n'est pas office sur cette becane
je regarderais ca se soir

merci

au plaisir

[mercatog]

F1 sur Split

Syntaxe
Split(expression[, delimiter[, limit[, compare]]])

delimiter Facultatif. Caractère de chaîne utilisé pour identifier les limites de sous-chaîne. S'il est omis, le caractère espace (" ") est utilisé comme séparateur par défaut. Si l'argument delimiter est une chaîne de longueur nulle, un tableau à un élément contenant toute la chaîne expression est renvoyé.