Discussion :

[Dadadidou]

Bonjour,

Je suis un peu nouveau dans le domaine de la macro et du langage VBA, bien que j'ai trouvé de l'aide ici, et je coince sur un petit truc.
J'ai 2 colonnes de données (des nombres décimaux), et je cherche à filtrer la colonne 1 sur un intervalle de +/- 0.05 autour de 1 puis 2 puis 3 ... puis 25, et de faire la moyenne des valeurs de la colonne 2 après filtrage et de copier cette moyenne dans une case.

Voici le code que j'ai (qui fonctionne) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
    Dim i As Integer
    Dim c As Range
    Dim TotalX As Double, MoyenneX As Double
    Dim CompteurX As Long, DerLigX
    Dim C1 As String, C2 As String
    Dim MaPlageX As Range
 
For i = 1 To 25
    CompteurX = 0
    TotalX = 0
 
    'Je filtre sur mon intervalle
    C1 = Replace(">=" & CStr(i - 0.05), ",", ".")
    C2 = Replace("<=" & CStr(i + 0.05), ",", ".")
    ActiveSheet.Range("G1", [G65000].End(xlUp)).AutoFilter Field:=1, Criteria1:=C1, _
    Operator:=xlAnd, Criteria2:=C2
 
    'Je sélectionne mes données triées
    DerLigX = Range("I65536").End(xlUp).Row
    Set MaPlageX = Range("I2:I" & DerLigX).SpecialCells(xlVisible)
 
    'Je fais la moyenne
        For Each c In MaPlageX
            TotalX = TotalX + c.Value
            CompteurX = CompteurX + 1
        Next c
        MoyenneX = (TotalX) / (CompteurX)
        Cells(i, 12) = i
        Cells(i, 13) = MoyenneX
Next i
End Sub

J'ai un souci qui m'en amène un autre. Par exemple, une fois filtré, je n'ai aucune valeur dans l'intervalle pour l'entier 16. Dans ce cas, j'aimerais étendre l'intervalle de recherche à +/- 0.1 pour la colonne 1 et calculer la moyenne de la colonne 2, mais je n'y arrive pas. J'avais pensé à modifier la sélection des données triées en testant si la plage est vide ou non de cette façon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
    'Je sélectionne mes données triées
    DerLigX = Range("I10000").End(xlUp).Row
    Set MaPlageX = Range("I2:I" & DerLigX).SpecialCells(xlVisible)
 
    If MaPlageX Is Nothing Then
       C1 = Replace(">=" & CStr(i - 0.1), ",", ".")
       C2 = Replace("<=" & CStr(i + 0.1), ",", ".")
       ActiveSheet.Range("G1", [G10000].End(xlUp)).AutoFilter Field:=1, Criteria1:=C1, _
       Operator:=xlAnd, Criteria2:=C2
       DerLigX = Range("I10000").End(xlUp).Row
       Set MaPlageX = Range("I2:I" & DerLigX).SpecialCells(xlVisible)
    End If

Mais quand je fais du pas à pas, quand i=16, ça ne rentre pas dans ma boucle IF, comme s'il la considérait non vide, ou qu'il ne la considère pas du tout.

Vous auriez une idée du problème ?

Merci d'avance

PS : Fichier joint en annexe, la macro est "Feuil1.Selection"

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub Test()
Const N As Byte = 25
Dim LastLig As Long
Dim Tb(1 To N, 1 To 2) As Double
Dim i As Byte, j As Byte
Dim Plage As Range
Dim C1 As String, C2 As String
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 1 To N
        For j = 1 To 2
            C1 = Replace(i - 0.05 * j, ",", ".")
            C2 = Replace(i + 0.05 * j, ",", ".")
            .Range("G1:G" & LastLig).AutoFilter Field:=1, Criteria1:=">=" & C1, Criteria2:="<=" & C2, Operator:=xlAnd
            If .Range("G1:G" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then
                Set Plage = .Range("I2:I" & LastLig).SpecialCells(xlCellTypeVisible)
                Tb(i, 1) = i
                Tb(i, 2) = Application.Average(Plage)
                Set Plage = Nothing
                Exit For
            End If
            .AutoFilterMode = False
        Next j
    Next i
    .Range("J1").Resize(N, 2) = Tb
End With
End Sub

[Dadadidou]

Wah, mais vous faites pour que ça fonctionne directement comme ça ?
Ça donne exactement ce que je veux, mais il y a des étapes que je ne comprends pas trop

Que font ces lignes : Tb(i, 1) = i
Tb(i, 2) = Application.Average(Plage) ?

Aussi, j'ai compris que la variable j permet de fixer l'intervalle à +/- 0.05 ou +/-0.1 selon sa valeur, mais j'ai l'impression que même si on trouve des valeurs dans l'intervalle +/-0.05, il refait les étapes pour l'intervalle +/-0.1 ?

En tout cas, merci beaucoup

[mercatog]

mais j'ai l'impression que même si on trouve des valeurs dans l'intervalle +/-0.05, il refait les étapes pour l'intervalle +/-0.1 ?

L'impression ou exactement? Compare avec les valeurs de ton fichier initial.

Si je me trompe, fais mois signe

En ligne 23 tu as un Exit For pour sortir de la boucle j (et ne garder que la valeur pour j=1 càd +/-0.05)


Pour ce qui est de Tb(i,1)=i. j'ai utilisé une variable tableau Tb (pour gagner un peut de temps) et je le transfère directement et en une seule fois vers la feuille.

Pour ton impression, je te propose de tester ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Test()
Const N As Byte = 25
Dim LastLig As Long
Dim Tb(1 To N, 1 To 3) As Double
Dim i As Byte, j As Byte
Dim Plage As Range
Dim C1 As String, C2 As String
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 1 To N
        For j = 1 To 2
            C1 = Replace(i - 0.05 * j, ",", ".")
            C2 = Replace(i + 0.05 * j, ",", ".")
            .Range("G1:G" & LastLig).AutoFilter Field:=1, Criteria1:=">=" & C1, Criteria2:="<=" & C2, Operator:=xlAnd
            If .Range("G1:G" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then
                Set Plage = .Range("I2:I" & LastLig).SpecialCells(xlCellTypeVisible)
                Tb(i, 1) = i
                Tb(i, 2) = Application.Average(Plage)
                Tb(i, 3) = 0.05 * j
                Set Plage = Nothing
                Exit For
            End If
            .AutoFilterMode = False
        Next j
    Next i
    .Range("J1").Resize(N, 3) = Tb
End With
End Sub

[Dadadidou]

J'ai compris comment tu faisais, c'est juste que n'étant pas très familier avec le codage, je ne suivais pas bien le cheminement

Merci de ton aide