Discussion :

[moi244]

Bonjour,
Dans Feuil1, j'aimerais chercher un mot clé : "Salaire", je pourrait avoir de 1 à 15 résultats. J'aimerais récupérer l'information qui se trouve à la cellule suivante : cells(numéro de la ligne de la cellule trouvée + 5 , 1) et le mettre dans sheets("Feuil2").Cells(5,9) et ainsi de suite, et ce, pour chaque résultat trouvé (comme j'ai dit précedement: une boucle avec to variable).
J'ai fait ce code par "record":

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Cells.Find(What:="Salaire", After:=ActiveCell _
        , LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False).Activate

Merci!

[mercatog]

Regarde l'aide sur la méthode Find, tu aura là bas un exemple qui boucle sur toutes les occurrences du mot cherché

[moi244]

Salut, j'ai essayé le code dans l'exemple. Mais je crois que je bloque vraiment!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub trouve()
 
With Worksheets(1).Range("a1:a500")
    Set c = .Find("Salaire", LookIn:=xlValues)
    Set fc = .FindNext(after:=c)
    If Not c Is Nothing Then
        firstAddress = c.Address
 
      For i = 13 To fc + 15
        Do
 
            Cells(11, 5) = c.Value
 
                    Cells(i, 6) = Cells(Right(fc.Address, 2) + 4, 3).Value
 
        Loop While Not c Is Nothing And c.Address <> firstAddress
     Next i
    End If
End With
 
End Sub

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Trouve()
Dim FirstAddress As String
Dim LastLig As Long
Dim i As Integer
Dim c As Range
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
 
    With .Range("A1:A" & LastLig)
        Set c = .Find("Salaire", LookIn:=xlValues, lookat:=xlPart)
        If Not c Is Nothing Then
            FirstAddress = c.Address
            Do
                c.Offset(5, 0).Copy Worksheets("Feuil2").Cells(5 + i, 9)
                i = i + 1
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> FirstAddress
        End If
    End With
End With
End Sub