Discussion :

[zouille]

salut a tous
voila , j'ai un code qui me pose probleme.
En fait il y a deux condition a verifier et en fonction du resltat de ces derneres , des actions différente a effectuer .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Private Sub BtnConfirm_click()
 
    With Sheets("listing")
 
        For i = 1 To 20
            If Cells(i, 1) = txt_noms Then ' Je verifie si le nom existe deja
                MsgBox ("Cette personne existe deja")
                combobox1 = txt_noms
                GoTo line1
            End If
        Next i
 
    End With
 
            If txt_noms = "" Or textbox9 = "" Or combobox2 = "" Then ' verification des case vide
                MsgBox ("Il manque une ou des case(s) a remplir")
            Else
                Sheets("listing").Range(A999) = txt_noms ' si tout ok je copie le nom de la personne dans la case
 
line1:
                Tri ' fonction que me remet la liste des noms dans l'ordre alphabetique, je ne sais pas comment on ecrit dans la derniere cellule d'une collone d'ou la case 999
                txt_noms.Visible = False
                BtnConfirm.Visible = False
                inicombobox1
                combobox1 = txt_noms
                End If
 
 
End Sub

voici mon probleme

Si la personne n'existe pas , je verifie que les case ne sont pas vide , la tout est ok
Par contre si la personne existe deja, ca ne verifie pas les case, la macro continue.

J'aimerais que la verif des case vide se fasse en premier et si aucune n'est vide , me dire ( éeme if) si la personne existe deja et continuait la fonction.

En fait , si la personne n'existe pas , je la cré puis je lui ajoute des valeur mais si elle existe , ca me le dit et ca lui ajoute les valeur.

J'espere que qqun m'a compris

merci

[mercatog]

Quelque chose comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub BtnConfirm_click()
Dim c As Range
 
If txt_noms = "" Or textbox9 = "" Or combobox2 = "" Then    ' verification des case vide
    MsgBox "Il manque une ou des case(s) a remplir"
Else
    With Worksheets("listing")
        'on cherche la cellule contenant txt_noms dans la colonne A
        Set c = .Range("A:A").Find(txt_noms, LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            Set c = Nothing
            MsgBox "Cette personne existe deja"
        Else
            .Cells(.Rows.Count, "A").End(xlUp)(2) = txt_noms
        End If
    End With
    Tri
    txt_noms.Visible = False
    BtnConfirm.Visible = False
    inicombobox1
    combobox1 = txt_noms
End If
End Sub