Discussion :

[moaleboss]

Bijour a tous et a toutes.

Aprés une recherche sur le forum, je n'ai pas trouvé mon bonheur, et mon meilleur ami, google, ne ma pas répondu :/
J'en fais donc appel a vous

Je voudrai connaitre l'heure system d'un serveur.
Explication. J'ai un serveur qui tourne (serveur PI), et je voudrai récupérer son heure system, sachant que je suis en LAN avec lui (réseau local koi).

Grand merci d'avance.

[HPJ]

Si c'est un serveur NTP: http://www.brigsoft.com/bsatomic/BSAtomicVbArticle.htm
ou sinon il reste encore le "net time".

[moaleboss]

hum, merci HPJ, je vais tester ca
Tu peux en dire plus sur le "net time"?

[HPJ]

Sous l'invite de commande, tu tapes "net time \\monserveur" pour connaître l'heure du serveur.

[HPJ]

Une fonction qui retourne l'heure du serveur dont le nom est passé en paramètre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
Private Declare Function NetRemoteTOD Lib "Netapi32.dll" ( _
    tServer As Any, pBuffer As Long) As Long
 
Private Type SYSTEMTIME
    wYear As Integer
    wMonth As Integer
    wDayOfWeek As Integer
    wDay As Integer
    wHour As Integer
    wMinute As Integer
    wSecond As Integer
    wMilliseconds As Integer
End Type
 
Private Type TIME_ZONE_INFORMATION
    Bias As Long
    StandardName(32) As Integer
    StandardDate As SYSTEMTIME
    StandardBias As Long
    DaylightName(32) As Integer
    DaylightDate As SYSTEMTIME
    DaylightBias As Long
End Type
 
Private Declare Function GetTimeZoneInformation Lib "kernel32" _
        (lpTimeZoneInformation As TIME_ZONE_INFORMATION) As Long
 
Private Declare Function NetApiBufferFree Lib "Netapi32.dll" _
        (ByVal lpBuffer As Long) As Long
 
Private Type TIME_OF_DAY_INFO
    tod_elapsedt As Long
    tod_msecs As Long
    tod_hours As Long
    tod_mins As Long
    tod_secs As Long
    tod_hunds As Long
    tod_timezone As Long
    tod_tinterval As Long
    tod_day As Long
    tod_month As Long
    tod_year As Long
    tod_weekday As Long
End Type
 
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
        (Destination As Any, Source As Any, ByVal Length As Long)
 
 
Public Function getRemoteTOD(ByVal strServer As String) As Date
 
    Dim result As Date
    Dim lRet As Long
    Dim tod As TIME_OF_DAY_INFO
    Dim lpbuff As Long
    Dim tServer() As Byte
 
    tServer = strServer & vbNullChar
    lRet = NetRemoteTOD(tServer(0), lpbuff)
 
    If lRet = 0 Then
        CopyMemory tod, ByVal lpbuff, Len(tod)
        NetApiBufferFree lpbuff
        result = DateSerial(tod.tod_year, tod.tod_month, _
                            tod.tod_day) + _
        TimeSerial(tod.tod_hours, tod.tod_mins - tod.tod_timezone, _
                   tod.tod_secs)
        getRemoteTOD = result
    Else
        Err.Raise Number:=vbObjectError + 1001, _
        Description:="cannot get remote TOD"
    End If
 
End Function

[moaleboss]

Merci. Mais (tampis si je passe pour un idiot :/ ) qu'est ce que je lui donne comme server? le nom, l'ip?

[HPJ]

Il suffit d'essayer et tu verras

Tu peux mettre soit l'un soit l'autre

[moaleboss]

Hum hum
Ben la, j'a une erreur. avec le code que tu ma passé, ca me renvoie "lRet=53" (juste avant le IF de la procédure getRemoteTOD).

Comment puis je savoir d'ou est ce que ca veut pas marcher? (enfin, je sais d'ou ca vien, mais, ca ne marche pas).

[HPJ]

http://msdn.microsoft.com/library/de...es__0-499_.asp
Err 53: Le nom ou l'adresse du serveur est invalide.

[moaleboss]

Tain, tsé koi, si je pouvais, je t'admirerai :p
lol

Grand merci, je vais chercher de mon coté. Si jamais le besoin s'en fais ressentir, je vous refais signes

Mais grand merci a toi HPJ
\\o \o/ o//

[moaleboss]

Je viens de me rendre compte qu'avec mon IP (127.0.0.1 :p) et mon IP locale, ca marche, et avec mon computer name, ca passe aussi, c que je dois pas avoir le bon nom de serveur alors :/
Merci

[HPJ]

Oui, c'est bien ce que signifie l'erreur 53.

[moaleboss]

Vi, je sais

C'est la raison pour laquelle j'ai testé aprés avec 127.0.0.1 (boucle locale) mon Computer Name, et mon IP Locale.

[moaleboss]

Ca marche, mais que avec mes IP de ma classe.
Ex : Je suis en 134.145.xxx.xxx et mon serveur, lui est en 172.16.xxx.xxx
Ca ne marche pas, quelqu'un a la soluce?
J'ai aussi essayé avec le nom de l'ordinateur, mais ca passe pas non plus :/

[moaleboss]

J'ai trouvé, c le rooteur qui bloque au milieu, je ne peux y accéder de cette manière, j'ai trouvé comment faire autrement, tampis