Discussion :

[pijaku]

Bonjour,

Comme ne l'indique pas le (trop court) titre de ce sujet, une utilisation des clés d'objets dictionary dans une variable tableau à deux dimensions, nous permet d'obtenir rapidement une jolie récap d'un classeur.

Je pars de ces hypothèses de départ :
Un classeur contenant 12 feuilles (mois), avec sur chaque feuille :
- Colonne A : des noms de vendeurs,
- Colonne B : des noms de produits,
- Colonne C : des quantités

Nous souhaitons obtenir, dans une feuille "Récap", les quantités de chaque produits vendus par chaque vendeurs.
Un TCD me direz vous?
Bien sur, pourquoi pas...
Je vous propose cette alternative sous forme de macro.

Le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Sub RécapAvecSommeDesColonnesC()
Dim Feuille As Worksheet, i As Long
Dim TablVendeurs(), DicoVendeurs As Object
Dim TablVentes(), DicoVentes As Object
Dim Sommes()
 
Set DicoVendeurs = CreateObject("Scripting.Dictionary")
Set DicoVentes = CreateObject("Scripting.Dictionary")
'remplissage des étiquettes de lignes et de colonnes sans doublons
For Each Feuille In ThisWorkbook.Worksheets
    If Feuille.Name <> "Récap" Then
        With Feuille
            TablVendeurs = .Range("A2", .Range("A" & Rows.Count).End(xlUp))
            For i = LBound(TablVendeurs, 1) To UBound(TablVendeurs, 1)
                If Not DicoVendeurs.exists(TablVendeurs(i, 1)) Then DicoVendeurs.Add TablVendeurs(i, 1), TablVendeurs(i, 1)
            Next i
            TablVentes = .Range("B2", .Range("B" & Rows.Count).End(xlUp))
            For i = LBound(TablVentes, 1) To UBound(TablVentes, 1)
                If Not DicoVentes.exists(TablVentes(i, 1)) Then DicoVentes.Add TablVentes(i, 1), TablVentes(i, 1)
            Next i
        End With
    End If
Next Feuille
'remplissage de la variable tableau 2D grâce aux clés de Dictionary
ReDim Sommes(1 To DicoVendeurs.Count, 1 To DicoVentes.Count)
For Each Feuille In ThisWorkbook.Worksheets
    If Feuille.Name <> "Récap" Then
        With Feuille
            For i = 2 To .Range("A" & Rows.Count).End(xlUp).Row
                Sommes(Application.Match(.Cells(i, 1), DicoVendeurs.keys, 0), Application.Match(.Cells(i, 2), DicoVentes.keys, 0)) = Sommes(Application.Match(.Cells(i, 1), DicoVendeurs.keys, 0), Application.Match(.Cells(i, 2), DicoVentes.keys, 0)) + .Cells(i, 3).Value
            Next i
        End With
    End If
Next Feuille
With Sheets("Récap")
    .Range("A2").Resize(DicoVendeurs.Count, 1) = Application.Transpose(DicoVendeurs.keys)
    .Range("B1").Resize(1, DicoVentes.Count) = DicoVentes.keys
    .Range("B2").Resize(UBound(Sommes, 1), UBound(Sommes, 2)) = Sommes()
End With
End Sub

Ci-joint une petite démo

Qu'en dites vous?

[Vadorblanc]

Bonjour
Bravo, propre et rapide,