Discussion :

[dimferte]

Bonjour,

J'essaie de faire une recherche multi-critères sur deux tables en m'inspirant de l'aide de Charles A. de 2005 publiée sur votre site.

Mes tables : - KALAM01_HVIPAT ( ses champs : PATNUM,SIPNOM,SIPPREN, PATNAISD, NUMARCH)
- Table_atalante ( ses champs : N° IPP, NUM_DOS_ATA)
les deux tables sont liées par PATNUM vers N° IPP;

Dans mon code VB il me reste semble-t-il deux problèmes :

1°) l'insertion du nom de ma table : Table_atalante
2°) et un problème sur ma ligne de code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.lblStats.Caption = DCount("*", "KALAM01_HVIPAT", SQLWhere) & " / " & DCount("*", "KALAM01_HVIPAT")

Cela fait des heures que je cherche la solution sans résultat; si une bonne âme pouvait m'aider je serais le plus heureux.
Avec mes remerciements anticipés.

[LedZeppII]

Bonjour,

Il te faut une instruction SQL de ce style

Code sql :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
SELECT PATNUM, SIPNOM, SIPPREN, PATNAISD, NUMARCH, NUM_DOS_ATA
FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.[N° IPP]

Dans la procédure événementielle de chargement du formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub Form_Load()
Dim SQL As String
Dim ctl As Control
 
For Each ctl In Me.Controls
    Select Case Left(ctl.Name, 3)
        Case "chk"
            ctl.Value = -1
 
        Case "lbl"
            ctl.Caption = "- * - * -"
 
        Case "txt"
            ctl.Visible = False
            ctl.Value = ""
 
        Case "cmb"
            ctl.Visible = False
 
    End Select
Next ctl
 
SQL = "SELECT PATNUM, SIPNOM, SIPPREN, PATNAISD, NUMARCH, NUM_DOS_ATA "
SQL = SQL & "FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.[N° IPP]"
Me.lstResults.RowSource = SQL
Me.lstResults.Requery
End Sub

Dans la sub RefreshQuery() on ne va plus pouvoir utiliser DCount car cette fonction ne supporte que les tables et les requêtes en tant qu'objets de la base de données.
On fera le comptage d'enregistrement via des instructions SQL du type SELECT Count(*) FROM ... avec DAO.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Private Sub RefreshQuery()
Dim SQL As String
Dim SQLWhere As String
Dim SQLCompteTout As String, SQLCompteWhere As String
Dim lgCompteTout As Long, lgCompteWhere As String
Dim db As DAO.Database, rs As DAO.Recordset
 
SQL = "SELECT PATNUM, SIPNOM, SIPPREN, PATNAISD, NUMARCH, NUM_DOS_ATA" & vbCrLf
SQL = SQL & "FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.[N° IPP]" & vbCrLf
SQL = SQL & "Where KALAM01_HVIPAT.PATNUM <> 0 "
 
SQLCompteTout = "SELECT Count(*) FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.[N° IPP]"
 
If Not Me.chkNumArchHex Then
    SQL = SQL & "And KALAM01_HVIPAT!NUMARCH like '*" & Me.txtRechNumArchHex & "*' "
 
End If
If Not Me.chkNom Then
    SQL = SQL & "And KALAM01_HVIPAT!SIPNOM  like '*" & Me.txtRechNom & "*' "
End If
If Not Me.chkprenom Then
    SQL = SQL & "And KALAM01_HVIPAT!SIPPREN like '*" & Me.txtRechPrenom & "*' "
End If
If Not Me.chkDateNaissance Then
    SQL = SQL & "And KALAM01_HVIPAT!PATNAISD like '*" & Me.txtRechDateNaissance & "*' "
End If
 
If Not Me.chkNumAta Then
    SQL = SQL & "And Table_atalante!Type  like '*" & Me.txtRechNumAta & "*' "
End If
 
SQLWhere = Trim(Right(SQL, Len(SQL) - InStr(SQL, "Where ") - Len("Where ") + 1))
 
SQL = SQL & ";"
 
SQLCompteWhere = SQLCompteTout & " WHERE " & SQLWhere
 
Set db=CurrentDb()
Set rs = db.OpenRecordset(SQLCompteTout)
if not rs.EOF then lgCompteTout = rs(0)
rs.Close
Set rs = db.OpenRecordset(SQLCompteWhere)
if not rs.EOF then lgCompteWhere = rs(0)
rs.Close
 
Me.lblStats.Caption = lgCompteWhere & " / " & lgCompteTout
Me.lstResults.RowSource = SQL
Me.lstResults.Requery
 
End Sub

Pour pouvoir utiliser DAO, il faut s'assurer d'avoir une référence VB à ...
"Microsoft DAO 3.6 Object Library" pour Acces 2000~2003
ou "Microsoft Office 12.0 Access database engine Object Library" pour Access 2007 (fichier .accdb)
ou "Microsoft Office 14.0 Access database engine Object Library" pour Access 2010 (fichier .accdb)

A+

[RMDIM]

Bonjour,

Je te remercie pour ton aide qui m'est fort précieuse; il me reste un problème que je n'arrive pas à résoudre:
- la ligne Set rs = db.OpenRecordset(SQLCompteWhere) ne lui convient pas

J'avoue ne pas bien comprendre pourquoi.

Merci encore pour une nouvelle suggestion.

[LedZeppII]

Bonjour,

Je pense que c'est un problème dans la syntaxe des critères de la clause WHERE.
Dans cette partie du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
If Not Me.chkNumArchHex Then
    SQL = SQL & "And KALAM01_HVIPAT!NUMARCH like '*" & Me.txtRechNumArchHex & "*' "
End If
 
If Not Me.chkNom Then
    SQL = SQL & "And KALAM01_HVIPAT!SIPNOM  like '*" & Me.txtRechNom & "*' "
End If
If Not Me.chkprenom Then
    SQL = SQL & "And KALAM01_HVIPAT!SIPPREN like '*" & Me.txtRechPrenom & "*' "
End If
If Not Me.chkDateNaissance Then
    SQL = SQL & "And KALAM01_HVIPAT!PATNAISD like '*" & Me.txtRechDateNaissance & "*' "
End If
 
If Not Me.chkNumAta Then
    SQL = SQL & "And Table_atalante!Type  like '*" & Me.txtRechNumAta & "*' "
End If

L'opérateur de comparaison LIKE n'est applicable qu'à des champs de type texte.
Y a-t-il des champs qui ne sont pas de type texte ?

A+

[RMDIM]

Bonjour,
Effectivement j'ai trois champs qui ne sont pas du TEXTE:
- NumArch = Numéro Auto
-NUM_DOS_ATA = Numérique
PATNAISD = Date/heure

J'ai essayé les syntaxes suivantes sans succès:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Private Sub RefreshQuery()
Dim SQL As String
Dim SQLWhere As String
Dim SQLCompteTout As String, SQLCompteWhere As String
Dim lgCompteTout As Long, lgCompteWhere As String
Dim db As DAO.Database, rs As DAO.Recordset
 
SQL = "SELECT PATNUM, SIPNOM,SIPPREN, PATNAISD, NUMARCH, NUM_DOS_ATA" & vbCrLf
SQL = SQL & "FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.IPP" & vbCrLf
SQL = SQL & "Where KALAM01_HVIPAT.PATNUM <> 0 "
 
SQLCompteTout = "SELECT Count(*) FROM KALAM01_HVIPAT INNER JOIN Table_atalante ON KALAM01_HVIPAT.PATNUM = Table_atalante.[N°IPP]"
 
If Not Me.chkNumArchHex Then
SQL = SQL & "And KALAM01_HVIPAT!NUMARCH = '" & Me.txtRechNumArchHex & "' "
End If
If Not Me.chkNom Then
SQL = SQL & "And KALAM01_HVIPAT!SIPNOM like '*" & Me.txtRechNom & "*' "
End If
If Not Me.chkprenom Then
SQL = SQL & "And KALAM01_HVIPAT!SIPPREN like '*" & Me.txtRechPrenom & "*' "
End If
If Not Me.chkDateNaissance Then
SQL = SQL & "And KALAM01_HVIPAT!PATNAISD = '" & Me.txtRechDateNaissance & "' "
End If
If Not Me.chkNumAta Then
SQL = SQL & "And Table_atalante!NUM_DOS_ATA = '" & Me.txtRechNumAta & "' "
End If
 
SQLWhere = Trim(Right(SQL, Len(SQL) - InStr(SQL, "Where ") - Len("Where ") + 1))
 
SQL = SQL & ";"
 
SQLCompteWhere = SQLCompteTout & " WHERE " & SQLWhere
 
Set db = CurrentDb()
Set rs = db.OpenRecordset(SQLCompteTout)
If Not rs.EOF Then lgCompteTout = rs(0)
rs.Close
Set rs = db.OpenRecordset(SQLCompteWhere)
If Not rs.EOF Then lgCompteWhere = rs(0)
rs.Close
 
Me.lblStats.Caption = lgCompteWhere & " / " & lgCompteTout
Me.lstResults.RowSource = SQL
Me.lstResults.Requery

Encore un grand merci pour ton aide.

[LedZeppII]

Bonsoir,

Pour des champs numériques :
L'opérateur Like fonctionne, mais tu perds en performance, en obligeant le moteur de base données à convertir le champ numérique en chaîne de caractère, afin de pouvoir la comparer à ce qui est à droite de l'opérateur Like.
Le plus approprié pour des Entiers est l'opérateur = , à droite duquel on met le nombre entier sans guillemets simples.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If Not Me.chkNumArchHex Then
SQL = SQL & "And KALAM01_HVIPAT!NUMARCH = " & Me.txtRechNumArchHex & " "
End If

Pour des champs dates :
L'opérateur Like peut aussi fonctionner mais, je dirai, de manière plus hasardeuse.
Là encore le moteur va convertir un champ non-texte en texte.
Il utilisera le format date des paramètres régionaux.
La manière classique de comparer un champ date à une date est par exemple (pour le 6-déc-2011) :

Code sql :

Sélectionner tout - Visualiser dans une fenêtre à part

ChampDate = #12/06/2011#

Dans ton code VB :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If Not Me.chkDateNaissance Then
SQL = SQL & "And KALAM01_HVIPAT!PATNAISD = #" & Format(Me.txtRechDateNaissance, "mm\/dd\/yyyy") & "# "
End If

Cela suppose aussi que VB est capable de reconnaître Me.txtRechDateNaissance comme étant une date.
Si tu imposes un format Date («Date, abrégé» par exemple) dans ton contrôle txtRechDateNaissance, ça aide.

A+