Discussion :

[iSayf]

Bonjour à tous,

Malgré mes nombreuses recherche, je n'arrive pas à surmonter ce problème..

Je souhaite affecter une couleur à chacune de mes barres sachant qu'il s'agit de données groupées :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
proc sgplot data=mydata;
	vbar date / response=x group=type FILLATTRS=???;
run;

FILLATTRS= style-element | (COLOR= color)

Auriez vous une solution hors changement des couleurs par défaut directement avec la proc template (style GraphData1 from GraphData1 etc.) car j'ai différents graphiques auxquels je souhaiterais affecter différentes couleurs afin de rester en accord avec les couleurs affectées aux graphiques obtenus par des proc gchart...



HELP ME

[datametric]

Peux-tu nous adresser des données ?

Tu veux une couleur par date ?

Si je pars de cela à partir de données utilisables de la SASHELP,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
proc sgplot data=sashelp.stocks;
vbar stock 
/response=volume fillattrs=(color="verylightgreen") 
datalabel 
datalabelattrs=(Color=Green Family=Arial Size=8 Style=Italic Weight=Bold);
 
title "Volume by Stock";
run;

On voit que fillattrs colorise toutes les barres. C'est ce que tu veux changer : une couleur par entreprise ?

[iSayf]

J'ai des données de ce type :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
data mydata;
	input date $ x type $;
	cards;
	2011-01 130 t1
	2011-01 50 t2
	2011-01 20 t3
 
	2011-02 220 t1
	2011-02 40 t2
	2011-02 70 t3
 
	2011-03 120 t1
	2011-03 80 t2
	2011-03 50 t3
	;
run;

Sur lesquelles je fais une proc sgplot :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
proc sgplot data=mydata;
	vbar date / response=x group=type;
run;

Afin d'obtenir un graphique de ce type :



Pour lequel je souhaite personnaliser les couleurs vert/orange/marron.

[datametric]

Tu définis une table avec tes modalités et les couleurs, que tu appelles ensuite. Ca te va ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Title;
 
data essai1;
input ID $ value $ linecolor $ fillcolor $;
datalines;
myid  F yellow yellow
myid  M red red
;
run;
 
proc sgplot data=sashelp.class dattrmap=essai1 ;
vbar age / response=height group=sex   attrid=myid;
run;
 
data essai2;
input ID $ value $ linecolor $ fillcolor $;
datalines;
myid  F pink pink
myid  M blue blue
;
run;
 
proc sgplot data=sashelp.class dattrmap=essai2 ;
vbar age / response=height group=sex   attrid=myid;
run;

[iSayf]

C'est tout simplement parfait parfait parfait !

[datametric]

[olivier.decourt]

Uniquement à partir de SAS 9.3, je précise, cette option DATTRMAP bien pratique.