Discussion :

[gigalia]

Bonjour,

Sur une feuille excel, j'ai des valeurs dans 2 colonnes (A et B)

La colonne A correspond à des articles et la colonne B correspond à des quantités. Dans la colonne A je peux avoir plusieurs fois le même article.

Je souhaite dans la colonne G copier les articles et mettre ensemble ce qui sont identiques et dans la colonne H avoir la somme des articles identiques.

Voici le début de code que j'ai mais je bloque au second If :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub concatenercai()
 
Dim cai As Range
Dim conc
 
For Each cai In Sheets("feuil2").Range("A:A")
 
    If cai <> "" Then
conc = cai.Value
    If conc <> Range("G:G") Then
cai.Copy ActiveSheet.Columns("G").Cells(Rows.Count, 1).End(xlUp)(2)
    End If
    End If
 
Next cai
 
End Sub

[jfontaine]

Bonjour,

Ta variable Conc n'est pas typé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim conc

Sur cette ligne tu lui donne la valeur d'une cellule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

conc = cai.Value

Et sur celle si tu la compare avec une plage de cellules

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If conc <> Range("G:G") Then

Une variable ne peut avoir plusieurs types.

Peux tu m'éclairer sur ce que doit faire cette condition.

[gigalia]

bonjour,

Je souhaite voir ci la valeur de la cellule de la colonne A est présente dans la colonne G.

Si non de la rajouter dans la colonne G.

[jfontaine]

Je te propose d'étudier ce code qui, je pense, fait ce que tu souhaites

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Sub concatenercai()
 
Dim rg As Range
Dim i As Long
Dim iDest As Long
 
'boucle sur la colonne A
For i = 1 To Range("A65536").End(xlUp).Row
    'Cherche la valeur de A dans la colonne G
    Set rg = Range("G:G").Find(Range("A" & i).Value)
 
    If rg Is Nothing Then
        'Ajoute si pas trouvé
        iDest = Range("G65536").End(xlUp).Row + 1
        Range("G" & iDest).Value = Range("A" & i).Value
        Range("H" & iDest).Value = Range("B" & i).Value
    Else
        'Ajoute le montant dans la colonne H
        rg.Offset(0, 1).Value = rg.Offset(0, 1).Value + Range("B" & i).Value
 
    End If
 
Next i
 
End Sub

[gigalia]

Bonjour,

Merci pour le code, ça marche. J'ai compris mon erreur et de plus par la suite j'étais partis sur un do loop. Il aurait fallu partir sur un set.

Merci pour tous je vais continuer a bosser.