Discussion :

[llmcky]

Bonjour à tous,

Je suis plus que débutant en écriture VBA ainsi qu'en Macro, et dans le cadre de mon travail je dois travailler avec cet outil.
J'ai crée un tableau Excel qui répertorie plusieurs documents avec des critères différents (contenu, marché, cible interrogée, etc.) sur la même page.

J'aimerai sur une feuille à part, créer un moteur de recherche qui trouvera tous les éléments correspondant (sur les différentes colonnes) de la recherche et d'afficher les lignes correspondantes dans une nouvelle fenêtre.

Merci pour votre aide!

[Yersin]

Sauf erreur de ma part, une macro ne me semble pas indispensable.

Une filtre automatique sur la ligne des intitulés ne serait-il pas plus simple à utiliser et à faire?

[llmcky]

Merci pour ton retour. Peut-être que j'utilise très mal les filtres automatique, mais malheureusement dans certaines cellules il y a beaucoup de texte (plusieurs mots qui se suivent). Donc si je cherche un mot en particulier dans une cellule, le filtre automatique n'arrivera pas à le trouver, je me trompe ?

En gros j'aimerai faire un moteur de recherche type google qui scanne les mots clés dans le corps du texte.
Je ne sais même pas si c'est possible.

[Yersin]

Merci pour ton retour. Peut-être que j'utilise très mal les filtres automatique, mais malheureusement dans certaines cellules il y a beaucoup de texte (plusieurs mots qui se suivent).

En séparant les mots clés par types dans des colonnes?

Donc si je cherche un mot en particulier dans une cellule, le filtre automatique n'arrivera pas à le trouver, je me trompe ?

Avec le filtre textuel, tu peux faire une recherche sur un ou deux mots contenus dans une cellule.

Sinon, sans aller jusqu'à refaire le moteur de Google, il faudra effectivement passer par une petite macro.

[llmcky]

Je suis sous excel 2003, j'ai l'impression qu'il n'y a pas la fonctionnalité filtre textuel dans la version 2003.

Effectivement je pense qu'une macro pourrait m'aider, cependant je ne sais pas comment cela fonctionne, une petite aide serait la bienvenue!

[Yersin]

Dans ton classeur Excel, tu dois avoir trois onglets:
- un avec les info sources
- un dans lequel voir le résultat
- un avec le champ de recherche et un bouton pour lancer la macro.

Dans le code, tu remarqueras que les noms des onglets sont des constantes.
Tu n'as plus qu'à les modifier pour les adapter à tes onglets

Par ailleurs, tu vas ouvrir le VBE (ALT+F11) et créer un nouveau module (Clic droit sur le projet, et ajouter un module), dans lequel tu colleras le code suivant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Const Sht_Ori = "Origine" ' Onglet de départ avec toutes les valeurs
Const Sht_Cib = "Cible" ' Onglet où s'affichera l'objet de la recherche
Const Sht_Acc = "Accueil" 'Onglet avec le champ des mots à rechercher et le bouton de lancement de la macro
 
Sub Recherche_Mot()
Dim Nbr_Lig As Long, Nbr_Col As Long, Nbr_Mot As Long, Num_Lig As Long
Dim i As Long, j As Long, k As Long, Tab_Temp
Dim Tst_Mot As Boolean
With ThisWorkbook
    With .Worksheets(Sht_Acc) 'Compte le nombre de mots
        Tab_Temp = Split(.Range("A1").Value, " ") 'Note les mots rechercher dans un tableau temporaire
        Nbr_Mot = UBound(Tab_Temp) 'Compte le nombre de mots à rechercher
    End With
    With .Worksheets(Sht_Ori) 'Dimensionne le tableau
        Nbr_Lig = .Range("A65536").End(xlUp).Row 'Compte le nombre de lignes
        Nbr_Col = .Range("IV1").End(xlToLeft).Column 'Compte le nombre de colonnes
    End With
    For i = 1 To Nbr_Lig 'Boucle sur les lignes
        Tst_Mot = False 'Réinitialise l'indicateur de test
        For j = 1 To Nbr_Col 'Boucle sur les colonnes
            For k = 0 To Nbr_Mot 'Boucle sur les mots
                If InStr(Worksheets(Sht_Ori).Cells(i, j).Value, Tab_Temp(k)) > 0 Then
                    Tst_Mot = True 'Test validé si au moins un mot est trouvé dans une ligne
                End If
            Next k
        Next j
        If Tst_Mot = True Or i = 1 Then 'Si le test est validée ou s'il s'agit de la ligne d'en tête copie de la ligne
            Num_Lig = Num_Lig + 1 'Incrémente le nombre de lignes de l'onglet cible
            Worksheets(Sht_Cib).Rows(Num_Lig).Value = Worksheets(Sht_Ori).Rows(i).Value
        End If
    Next i
End With
End Sub

Une fois la macro installée, va dans l'onglet de lancement (l'accueil) et place un bouton pour lancer la macro que tu viens de mettre.

Pour le moment, la macro permet simplement de recopier les lignes de l'onglet d'origine vers l'onglet cible lorsqu'elles comportent aux moins un mot.

Pour faire un test sur la présence de tous les mots, ou pour mettre les mots en couleur, etc, je te laisse le plaisir de bidouiller ce bout de code.

En espérant t'avoir aidé.