Discussion :

[8e8eClo]

Bonjour,

J'ai une feuille qui comporte ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
 
 
  If Not Intersect(Target, Range("AF6")) Is Nothing Then
    With Target
      Select Case Target.Value
        Case Is = "Rédaction"
          .Interior.ColorIndex = 16
        Case Is = "Mise en concurrence"
          .Interior.ColorIndex = 3
        Case Is = "Analyse"
          .Interior.ColorIndex = 45
        Case Is = "En cours"
          .Interior.ColorIndex = 43
        Case Is = "Terminé"
          .Interior.ColorIndex = 47
      End Select
    End With
  End If
 
 
If Not Application.Intersect(Target, Range("AF6")) Is Nothing Then
Range("AF141") = Range("AF6").Value
Range("AF289") = Range("AF6").Value
Range("AF452") = Range("AF6").Value
Range("AF141").Interior.Color = Range("AF6").Interior.Color
Range("AF289").Interior.Color = Range("AF6").Interior.Color
Range("AF452").Interior.Color = Range("AF6").Interior.Color
End If
 
 
End Sub

Il fonctionne parfaitement sauf quand je protège la feuille.
En effet, j'ai un bug au niveau des .interior.colorindex suivant la valeur de AF6
Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 .Interior.ColorIndex = 16

Comment faire pour contourner ce problème.

PS : je suis débutant ...


Merci

[tarnx]

Bonjour,

Tu peux ôter la protection de la feuille au début de ta macro puis la remettre à la fin de l'exécution avec les instructions Protect/Unprotect.

[8e8eClo]

J'ai ajouté :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Unprotect

au tout début et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Protect

à la fin.

Mais maintenant il bug à

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("AF289") = Range("AF6").Value

[mercatog]

Protège ta feuille comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Protect UserInterfaceOnly:=True

Sinon, pour le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
 
With Target
    If .Address(0, 0) = "AF6" Then
        Select Case .Value
            Case Is = "Rédaction": .Interior.ColorIndex = 16
            Case Is = "Mise en concurrence": .Interior.ColorIndex = 3
            Case Is = "Analyse": .Interior.ColorIndex = 45
            Case Is = "En cours": .Interior.ColorIndex = 43
            Case Is = "Terminé": .Interior.ColorIndex = 47
            Case Else: .Interior.ColorIndex = xlNone
        End Select
        Application.EnableEvents = False
        .Copy Range("AF141,AF289,AF452")
        Application.EnableEvents = True
    End If
End With
End Sub

[8e8eClo]

Bonjour,


J'ai dû bidouiller un peu le code mais ça fonctionne !

Merci !