Discussion :

[dd16]

Bonjour

Je voudrais récupérer les longueurs des contenus d'un champ LONG.
J'ai essayé avec le fonction length() mais rien à faire.
J'ai essayé de convertir mon champ avec to_lob, substr ... et j'ai constamment une erreur 00932.

Merci de vos lumières, je sèche un peu.

[mnitu]

working with long columns

[laurentschneider]

LONG est moyenâgeux.. pour y accéder depuis PLSQL, il faut employer l'ennuyeux package DBMS_SQL.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
create or replace function size_of_long(r rowid, column_name varchar2, table_name varchar2) return number is
  c number := dbms_sql.open_cursor;  f number;  v varchar2(32767);
  len number := 0;  tot_len number := 0;  pos number := 0;
begin
  dbms_sql.parse(c,'select "'||column_name||'" from "'||table_name||'" where rowid='''||r||'''',dbms_sql.native);
  dbms_sql.define_column_long(c,1);
  f:= dbms_sql.execute_and_fetch(c);
  loop
    dbms_sql.column_value_long(c,1,32767,pos,v,len);
    exit when len=0;
    pos := pos + len;
    tot_len := tot_len +len;
  end loop;
  return tot_len;
end;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
SQL> select size_of_long(rowid,'X','T'),x from t
 
SIZE_OF_LONG(ROWID,'X','T') X                                                 
--------------------------- ----------------------
                          9 blablabla

[dd16]

Merci toutes cour les informations.

Je suis obligé d'employer le type LONG pour l'instant car le OleDB de Microsoft ne sais pas gérer les CLOB et j'ai des soucis avec les OleDB d'Oracle sous Delphi.