Discussion :

[Galere05]

Bonjour à tous,

je me casse la tete depuis un bon, moment sur un simple copier coller. je vous joins le code. Il me sort une erreur 1004, pb avec autofilter.
Ce que je veux faire: filtrer une base, copier le filtrage vers un autre classeur et mettre cette copie à la suite

Merci pour l'aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub FiltreCopie()
'
' FiltreCopie Macro
'
 
For i = 18 To 25 Step 1
    Sheets("BDD_BDC").Select
    Selection.AutoFilter
    ActiveSheet.Range("$A$1:$Y$2590").AutoFilter Field:=i, Criteria1:="<>"
    ActiveSheet.Range("A247:A2502,J247:Y2502").Copy
    Sheets("presse papier").Select
    Range("A" & Sheets("presse papier").Cells(Rows.Count, 1).End(xlUp).Row).Select
    ActiveSheet.Paste
Next i
 
End Sub

[mercatog]

Bonjour
Une petite explication est nécessaire
tu fais l'autofilter sur plusieurs colonnes et enfin tu copie les lignes visibles?

Si c'est affirmatif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub FiltreCopie()
Dim LastLig As Long
Dim i As Byte
 
Application.ScreenUpdating = False
With Sheets("BDD_BDC")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    For i = 18 To 25
        .Range("A1:Y" & LastLig).AutoFilter field:=i, Criteria1:="<>"
    Next i
    If .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then
        .Range("A2:A" & LastLig & ",J2:Y" & LastLig).SpecialCells(xlCellTypeVisible).Copy Sheets("presse papier").Cells(Sheets("presse papier").Rows.Count, 1).End(xlUp)(2)
    End If
    .AutoFilterMode = False
End With
End Sub

[Galere05]

oui c'est exactement cela. Filtre puis copie de ce qui est visible

[Galere05]

Ca fonctionne très bien, juste en mettant le Next i à la fin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub FiltreCopie()
Dim LastLig As Long
Dim i As Byte
 
Application.ScreenUpdating = False
With Sheets("BDD_BDC")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    For i = 18 To 25
        .Range("A1:Y" & LastLig).AutoFilter field:=i, Criteria1:="<>"
    Next i
    If .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count > 1 Then
        .Range("A2:A" & LastLig & ",J2:Y" & LastLig).SpecialCells(xlCellTypeVisible).Copy Sheets("presse papier").Cells(Sheets("presse papier").Rows.Count, 1).End(xlUp)(2)
    End If
    .AutoFilterMode = False
End With
End Sub

merci beaucoup!



Petite question quand même, à quoi correspond le (2)?

[mercatog]

Petite question quand même, à quoi correspond le (2)?

Pour comprendre, teste ce petit code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub test()
Range("A1")(2).Interior.ColorIndex = 3 'rouge
Range("A1")(2, 3).Interior.ColorIndex = 4 'vert
End Sub

[Galere05]

merci c'est compris.

par contre, bizarrement j'ai une erreur 9 "l'indice n'appartient pas à la selection" la seul modif que j'ai faite a été de déplacer le next en dessous du autofilter false.

l'erreur survient juste à la ligne en dessous du if