Discussion :

[gigalia]

Bonjour,

Je souhaiterais à l'aide d'une macro recherche un numéro sur toutes les feuilles et dans toutes les cellules existantes.

Pour ce faire je souhaiterais utilisé un do/loop. Je me sert de ce do/loop pour trouver une feuille par rapport à son nom :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 
Dim ind As Integer
 
Do While ind <= ThisWorkbook.Sheets.Count
 If ThisWorkbook.Sheets(ind).Name = ThisWorkbook.Sheets("Feuil1").Range("A50").Text Then
            Exit Do
        End If
    ind = ind + 1
Loop

Il me faudrait quelque chose de simillaire mais comme dit pour trouver dans une cellule d'une feuille autre que ma feuil1 la valeur donnée.

[mercatog]

Bonjour

Pour ton cas, une proposition avec For Each Next (on connait la collection des feuilles de ton classeur)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Test()
Dim Sh As Worksheet
Dim c As Range
Dim Rech As String
Dim Trouve As Boolean
 
Rech = "toto"                                    'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Feuil1" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            MsgBox "Occurence du mot " & Rech & " trouvée en " & Sh.Name & "!" & c.Address(0, 0)
            Set c = Nothing
            Trouve = True
        End If
    End If
Next Sh
If Not Trouve Then MsgBox "Aucune occurence du mot " & Rech
End Sub

[gigalia]

Merci Mercatog pour ta réponse, j'ai facilement pu l'adapté à ma macro.

Petites question : la valeur cherchée ne peut être présente qu'à un seul autre endroit que la feuil1. Il ne peut y avoir cette valeur sur plusieurs feuilles ou plusieurs cellules. Donc est ce qu'un Do/Loop ne serait pas mieux?

[mercatog]

Pour arrêter la recherche dès que le mot cherché est trouvé, j'ai ajouté un Exit For

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Test()
Dim Sh As Worksheet
Dim c As Range
Dim Rech As String
Dim Trouve As Boolean
 
Rech = "toto"                                    'Mot à rechercher
For Each Sh In ThisWorkbook.Worksheets           'Pour chaque feuille dans ce classeur
    If Sh.Name <> "Feuil1" Then                  'Si le nom de la feuille est différent de Feuil1
        Set c = Sh.UsedRange.Find(Rech, LookIn:=xlValues, LookAt:=xlWhole)    'on fais la recherche du mot dans la feuille
        If Not c Is Nothing Then
            MsgBox "Occurence du mot " & Rech & " trouvée en " & Sh.Name & "!" & c.Address(0, 0)
            Set c = Nothing
            Trouve = True
            Exit For                             'Ici pour arrêter la recherche dans les autres feuilles dès qu'on trouve le mot recherché
        End If
    End If
Next Sh
If Not Trouve Then MsgBox "Aucune occurence du mot " & Rech
End Sub

[gigalia]

Re,

Dans ta macro le resultat de la recherche c'est "c"? Et "c" est une cellule?

[mercatog]

En effet, "c" est la cellule trouvé (de type Range) avec:
c.address son adresse
c.value sa valeur
c.row sa ligne
c.column sa colonne