Discussion :

[Wawa07]

Salut tout le monde,
je suis entrain de faire des test de macro, mais je suis (encore) face à un probleme.
Dans une macro de mise en forme, il y a une automatisation de conversion de données. Or le problème est qu'il y a pas toujours des données dans ces colonnes; alors excel "débogge"

Voila ma macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Exemple ()
Range("BL1:BL" & dlg).TextToColumns Destination:=Range("BL1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="#"
Range("BQ1:BQ" & dlg).TextToColumns Destination:=Range("BQ1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="#"
Range("BV1:BV" & dlg).TextToColumns Destination:=Range("BV1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="#"
Range("CA1:CA" & dlg).TextToColumns Destination:=Range("CA1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="#"
Range("CF1:CF" & dlg).TextToColumns Destination:=Range("CF1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=False, _
        Semicolon:=False, Comma:=False, Space:=False, Other:=True, OtherChar:="#"
 
 
'Range("H:H,W:W,Y:Y,AA:AB,AD:AD,AF:AG,AI:AI,AK:AL,AN:AN,AP:AQ,AS:AS,AU:AV,AX:AX,AZ:BA,BC:BC,BE:BF,BH:BH,BJ:BK,BM:BM,BO:BP,BR:BR,BT:BU,BW:BW,BY:BZ,CB:CB,CD:CE,CG:CG,CI:CJ,CL:CL").Delete Shift:=xlToLeft
 
End sub

Je cherche une solution pour faire en sorte que, si la colonne sélectionnée est vide, alors la macto passe à la suivante.
par exemple: la colonne BV est vide, au lieu de bloquer, la macro voit que la colonne est vide, elle passe à la conversion de CA.

C'est possible que ce soit quelque chose comme "if row(bv1:bv).empty then next ... "

Bref vous l'avez compris, je ne suis pas trés fort pour le VBA ...!

Est ce que c'est possible de faire ca? et est ce que quelqu'un pourrait m'aider?

Merci d'avoir lu mon message. A bientot

[mercatog]

Bonsoir

Adapte le sub Exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Convert(Rng As Range)
 
If Application.CountA(Rng) > 0 Then Rng.TextToColumns Destination:=Rng(1, 1), DataType:=xlDelimited, TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Other:=True, OtherChar:="#"
End Sub
 
Sub Exemple()
Dim Dlg As Long
 
With Sheets("Feuil1")                                                'à adapter
    Dlg = .Cells(.Rows.Count, "A").End(xlUp).Row                     'A adapter en fonction de la colonne de recherche de la dernière ligne remplie
    Convert .Range("BL1:BL" & Dlg)
    Convert .Range("BQ1:BQ" & Dlg)
    Convert .Range("BV1:BV" & Dlg)
    Convert .Range("CA1:CA" & Dlg)
    Convert .Range("CF1:CF" & Dlg)
End With
End Sub