Discussion :

[Boldug]

Bonjour à Tous,

Etant débutant en programmation, j'essaie de trouver le moyen de créer une macro qui puisse transposer les valeurs d'un tableau dans une seule colonne.

Bien-entendu, il y a quelques complications, à savoir :

- Le tableau peut varier en ligne et en colonne.
- Ce même tableau comporte des cellules vides (des fois des lignes entièrement vides) que je ne veux pas récupérer dans la colonne finale.
- Le tableau initial est présent dans un classeur et la colonne finale est dans un autre classeur.
- Je veux que les valeurs rapatriés dans la colonne respecte l'ordre de lecture du tableau (lecture ligne par ligne de gauche à droite)

Je vous joins un fichier excel test.xls pour pouvoir comprendre au mieux ma requête.

Je remercie d'avance ceux qui pourront m'éclairer et m'initier en douceur à la programmation vba excel ^^ (En parallèle, je continue ma recherche sur le net)

[bellande]

bonjour,
en feuille 1, on a les données et en feuille 3 on a le résultat.
On peut mettre un nom entre guillemet à la place d'un numéro de feuille si on préfère

Les boucles imbriquées parcours les cellules dans l'ordre que tu as demandé
le test (if) permet de traiter seulement les cellules non vides et le compteur cpt permet de passer à la ligne suivante :

Ca donne cela. Je répondrai avec plaisir à tes questions

faire un bouton sur la feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub CommandButton1_Click()
  ConstruireTableau Range("A1"), Range("G7")
End Sub

Faire : insertion module et coller ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Public Sub ConstruireTableau(ByVal Cellule1 As Range, ByVal Cellule2 As Range)
Dim Ligne As Integer
Dim Colonne As Integer
Dim Cpt As Integer
 
Cpt = 1
For Ligne = Cellule1.Row To Cellule2.Row
   For Colonne = Cellule1.Column To Cellule2.Column
      If Sheets(1).Cells(Ligne, Colonne).Value <> "" Then
         Sheets(3).Range("A" & Cpt).Value = Sheets(1).Cells(Ligne, Colonne).Value
         Cpt = Cpt + 1
      End If
   Next Colonne
Next Ligne
 
End Sub

[pgz]

Bonjour.

Voici une autre façon de faire. Le code est plus long mais il s'exécute plus rapidement, si le tableau grossit...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub subBoldug()
Dim vL As Variant, vR As Variant
Dim oShL As Excel.Worksheet, oShR As Excel.Worksheet, oRngR As Excel.Range
Dim i As Long, j As Integer, k As Long, nbCells As Long
 
'instanciation de la feuille de données (L) et de résultat (R)
Set oShL = ThisWorkbook.Worksheets("Tableau_initial")
Set oShR = ThisWorkbook.Worksheets("colonne_finale")
 
'lecture du tabeau de données
vL = oShL.UsedRange.Value
 
'calcul du nombre de cellules lues
nbCells = UBound(vL, 1) * UBound(vL, 2)
 
'nettoyage de la feuille de résultats
oShR.UsedRange.ClearContents
 
'dimensionnement de vR
Set oRngR = oShR.Range("A1:A" & nbCells)
vR = oRngR.Value
 
'copie des valeurs de vL dans vR
k = 1
For i = 1 To UBound(vL, 1)
    For j = 1 To UBound(vL, 2)
        If Not IsEmpty(vL(i, j)) Then
            vR(k, 1) = vL(i, j)
            k = k + 1
        End If
    Next j
Next i
 
'copier le résultat dans la feuille
oRngR.Value = vR
 
'libérer les variables
Set oRngR = Nothing
Set oShL = Nothing
Set oShR = Nothing
vL = Empty
vR = Empty
 
End Sub

Cordialement,

PGZ

[Boldug]

Une réponse rapide juste pour vous remercier !! Je vais maintenant étudier vos macros minutieusement et vous tiendrais au courant !! C'est pour le boulot mais je veux vraiment progresser en vba excel, donc je vais potasser ce weekend aussi ^^

Merci encore et Bon weekend !