Discussion :

[Mondapar]

Bonjour!

Je sais que vous ne préconisez pas l'envoi de pièces jointes, mais mon cas nécessite un exemple pour que vous puissiez vous y retrouver sans trop de peine.

Voilà maintenant 2 jours que j'essaie de trouver une solution à ma situation, sans succès...

Je vous invite d'ailleur à ouvrir le fichier joint pour mieux comprendre mon propos.

Je travaille présente présentement dans un classeur Excel contenant des informations sur des liaisons hertziennes (onde radio) entre diverses tours. Le premier onglet ("Données") contient déjà toutes les informations dont j'ai besoin. Les trois autres onglets sont également déjà présent, portent déjà leur nom respectif (A,B et C)et contiennent déjà le tableau "Stations en liaison" vierge. L'algorithme que je cherche ira chercher les infos du premier onglet et les placera dans le bon onglet, au bon endroit.

L'exemple comporte beaucoup d'explication, avec un code de couleur, et c'est pourquoi je n'entrerai pas plus dans les détails ici, ne voulant pas créer de confusion.

Si toutefois il vous manque des infos, n'hésitez pas m'écrire!

Merci d'avance à tout ceux qui prendront la peine de me lire!

[pgz]

Bonjour.


Deux précisions :

• Le tableau de la feuille "Données" est déjà triée clé1 = départ; clé2 = arrivée. C'est toujours comme cela et on peut y compter?
• Ce même tableau commence par des lignes vierges, c'est normal?

PGZ

[Mondapar]

Bonjour!

Oui ce fichier est toujours trié ainsi et les lignes vierges sont aussi toujours présentes.

Merci!

[pgz]

Bonsoir.

Dans la routine que je te propose, j'utilise des noms définis :

• Dans la feuille "données" le contenu du tableau (sans les lignes de titres) a été nommé "npTableauLiaisonsH". Ce nom est d'étendue = classeur
• Dans chaque autre feuille le tableau à renseigner (sans lignes de titres) a été nommé "nfpStations". C'est le même nom sur chaque feuille et donc l'étendue de chaque nom est celui de sa feuille.

Pour exécuter la procédure il faut ainsi définir 1 nom de classeur et 3 noms de feuille.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub Mondapar()
Dim oRng As Excel.Range
Dim v As Variant, w As Variant
Dim i As Integer, k As Integer
Dim sDepart As String, sRecep As String
 
v = ThisWorkbook.Names("npTableauLiaisonsH").RefersToRange.Value
 
sDepart = vbNullString
For i = 1 To UBound(v, 1)
    If v(i, 1) <> "" Then
        If sDepart <> v(i, 1) Then
            If Not IsEmpty(w) Then oRng.Value = w
            sDepart = v(i, 1)
            sRecep = vbNullString
            Set oRng = ThisWorkbook.Worksheets(sDepart).Names("nfpStations").RefersToRange
            oRng.ClearContents
            w = oRng.Value
            k = 1
        End If
 
        If sRecep <> v(i, 2) Then
            sRecep = v(i, 2) 'station réception
            w(k, 1) = sRecep 'station réception
            w(k, 6) = v(i, 6) 'azimuth
            w(k + 1, 6) = v(i, 3) 'distance
            w(k + 2, 6) = v(i, 4) & " , " & v(i, 5)
            k = k + 3
        Else
            w(k, 6) = v(i, 4) & " , " & v(i, 5)
            k = k + 1
        End If
    End If
Next i
 
oRng.Value = w
 
Set oRng = Nothing
v = Empty
w = Empty
End Sub

Cordialement,

PGZ