Discussion :

[AstridT]

Bonjour,

Comment puis-je parcourir un range d'un nombre de lignes variable de la dernière ligne vers la première (du range mais pas de la feuille) pour supprimer certaines lignes selon une condition ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Set fin = Worksheets("Feuil1").Range("A5").End(xlDown)
 
For Each cell in Worksheets("Feuil1").Range(????)
    If cell.Offset(, 3).Value = "" Then
        cell.Select
        Selection.EntireRow.Delete
    End If
Next

J'ai essayé différentes choses avec End(xlDown/xlUp) mais au final il me prend toujours mon range de haut en bas et non de bas en haut.

Y'a t'il un équivalent du "step -1" du for pour un for each ?

Merci d'avance

[gourmand]

je dit surement une connerie, mais a tu essayer d'inversé l'intérieur du range?

range("A1:A10") => range("A10:A1")

[AstridT]

J'avais essayé oui mais c'est pris en compte de la même façon, donc de haut en bas

[AstridT]

Merci mercatog !
J'ai utilisé la première méthode que tu donnes et ça fait exactement ce qu'il me fallait !

P.S: Je me permet, j'ai posté un autre message, sur la recherche d'élément dépendant de deux champs dans un tcd, tu n'aurais pas une idée please ?
http://www.developpez.net/forums/d10...sieurs-champs/
Je n'ai pas eu de réponse et j'ai épuisé toutes mes idées depuis longtemps...
Merci d'avance

[mercatog]

J'ai utilisé la première méthode que tu donnes et ça fait exactement ce qu'il me fallait

pourtant le 2ème code est le plus rapide. mais bon.

Je n'ai pas eu de réponse et j'ai épuisé toutes mes idées depuis longtemps...

peut être ta formulation n'est pas claire.

[mercatog]

Pour ta question de boucle For each ne permet pas cela.
Essaie ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub test2()
Dim LastLig As Long, i As Long
 
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
 
    For i = LastLig To 5 Step -1
        If .Range("D" & i).Value = "" Then .Rows(i).Delete
    Next i
End With
End Sub

Ou autrement et sans boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test3()
Dim LastLig As Long
 
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    On Error Resume Next
    .Range("D5:D" & LastLig).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End With
End Sub

@ Gourmand
Essaies ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
 
With Worksheets("Feuil1")
    For Each c In Range("A20:A5")
       Debug.Print c.Address
    Next c
End With
End Sub

Ta proposition n'est pas valable.