Discussion :

[Automnep]

Bonjour,

Je dispose actuellement d'une macro qui me permet d'associer un mois en lettres a une date au format dd/mm/yyyy.

Par exemple, si j'ai une colonne A avec

12/02/2010
04/11/2011
05/08/2011

en cliquant sur ma macro j'obtiens dans la colonne B

Fevrier
Novembre
Aout

Le probleme c'est que je traite de tres grandes quantites de donnees et que mon ordinateur a parfois besoin de plus de 5mn pour effectuer la macro. Serait-ce possible d'optimiser le bout de code afin d'accelerer le processus ?

Voici le code que j'utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Button2_Click()
Dim i As Integer
 
Worksheets("Arval Reports").Activate
For i = 1 To Range("S65536").End(xlUp).Row
Range("AB" & i).Formula = "=TEXT(S" & i & ",""MMMMMMMMM"" )"
Next i
 
End Sub

avec AB la colonne ou atterissent les mois en lettre, et S la colonne ou se trouvent les mois en dd/mm/yyyy

Merci d'avance !

[mrtrampo]

Tu peux définir toutes tes formules en une seule fois, et sans avoir à activer la feuille en plus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Arval Reports").Range("AB1:AB" & Range("S65536").End(xlUp).Row).Formula = "=TEXT(S1,""mmmm"")"

Et ça marche pareil avec les valeurs, si ça peut te servir un jour

[mercatog]

Bonjour
Ton code sans boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Button2_Click()
Dim i As Long
 
Application.Calculation = xlCalculationManual
With Worksheets("Arval Reports")
    i = .Cells(.Rows.Count, "S").End(xlUp).Row
    With .Range("AB1:AB" & i)
        .Formula = "=TEXT(S1,""mmmm"" )"
        .Value = .Value
    End With
End With
Application.Calculation = xlCalculationAutomatic
End Sub

[Automnep]

Merci a vous, j'ai pris le code de Mercatog, ce qui se faisait avant en 5mn+ se fait maintenant en une fraction de seconde