Discussion :

[torvald]

Bonjour à tous,

J'ai un fichier excel avec des colonnes avec des valeurs :

0h 0mn 37s
2h 1mn 14s
0h 18mn 12s
0h 1mn 55s
0h 36mn 34s
0h 1mn 5s

Est-il possible à l'aide d'une macro de les mettre au format:

00H00m37s
02h01m14s
00h18m12s
00h01m55s
00h36m34s
00h01m05s

Merci de votre aide.

[Theze]

Bonjour,

Regarde si cela te conviens :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Heure()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim Heures As Integer
    Dim Minutes As Integer
    Dim Secondes As Integer
 
    'plage de recherche en colonne A
    Set Plage = Range([A1], Range("A" & Rows.Count).End(xlUp))
 
    For Each Cel In Plage
 
        'extrait les heures, minutes et secondes
        Heures = Left(Cel, InStr(Cel, "h") - 1)
        Minutes = Mid(Cel, InStr(Cel, " ") + 1, InStr(Cel, "mn") - InStr(Cel, " ") - 1)
        Secondes = Mid(Cel, InStrRev(Cel, " ") + 1, InStr(Cel, "s") - InStrRev(Cel, " ") - 1)
 
        'formate et inscrit dans la cellule voisine
        Cel.Offset(0, 1) = Format(Heures, "00h") & Format(Minutes, "00m") & Format(Secondes, "00s")
 
    Next Cel
 
End Sub

Hervé.

[torvald]

Super ça marche nickel mais ça le copie sur la colonne suivante on pourrait pas l'avoir sur la même colonne. Merci encore

Merci c'est bon j'ai vu encore merci

Excuse moi de te déranger Hervé et si cela concerne toutes les feuilles d'un classeur avec plusieurs colonnes (F, G, H, J, M) par feuilles.

[Theze]

Bonsoir,

Avec la proc ci-dessous (issue de la 1 ère), toutes les feuilles du classeur sont passées en revue pour les colonnes F, G, H, J, M et les heures sont remplacées dans la cellule par le nouveau format. Fais un test sur une copie de ton classeur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub Heure()
 
    Dim Fe As Worksheet
    Dim Plage As Range
    Dim Cel As Range
    Dim Heures As Integer
    Dim Minutes As Integer
    Dim Secondes As Integer
 
    'recherche dans toutes les feuilles du classeur
    For Each Fe In Worksheets
 
        'plage de recherche en colonne F, G, H, J, M
        With Fe
 
            Set Plage = Union(.Range(.[F1], .[F65536].End(xlUp)), _
                              .Range(.[G1], .[G65536].End(xlUp)), _
                              .Range(.[H1], .[H65536].End(xlUp)), _
                              .Range(.[J1], .[J65536].End(xlUp)), _
                              .Range(.[M1], .[M65536].End(xlUp)))
 
        End With
 
        For Each Cel In Plage
 
            'extrait les heures, minutes et secondes
            Heures = Left(Cel, InStr(Cel, "h") - 1)
            Minutes = Mid(Cel, InStr(Cel, " ") + 1, InStr(Cel, "mn") - InStr(Cel, " ") - 1)
            Secondes = Mid(Cel, InStrRev(Cel, " ") + 1, InStr(Cel, "s") - InStrRev(Cel, " ") - 1)
 
            'formate et inscrit dans la cellule
            Cel = Format(Heures, "00h") & Format(Minutes, "00m") & Format(Secondes, "00s")
 
        Next Cel
 
    Next Fe
 
End Sub

Hervé.

[torvald]

Salut Hervé,

Merci ça marche nickel je peux t'embêter un peu ??

[Theze]

Bonsoir torvald,

Tu ne m'embête pas du tout, tu peux poser tes questions et j'essairai d'y répondre du mieux possible mais demain soir, je dois partir maintenant.

Hervé.