Discussion :

[dave.bonnin]

Bonjour,

Je vais essayer de détailler mon problème car apres de nombreuses recherche je n'arrive pas à me dépatouiller tout seul.

J'ai un fichier excel.
2 feuilles: Bilan 2011 et Janvier (puis février, ...)
dans Bilan 2011 j'ai de D3à D113 des noms qui vont me servire de reference

dans la feuille janvier j'ai dans la colonne A des noms et dans la B un nombre.

Ce que j'aimerais faire c'est que pour la feuille janvier et colonne A, il aille verifier si il trouve le meme nom dans D3 a D113 de bilan 2011. Si oui rien ne se passe, mais si non, copier cette valeur(A) et celle d'a coté(B) par exemple dans la cellule E1 et F1

Puis on passe a la cellule suivante de la colonne A et si verif nulle on copie sur E2 et F2 et ainsi de suite.


Merci de votre aide

[gFZT82]

Bonjour,

Voila un début

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub Cherche()
    Dim ShRef As Worksheet, ShMois As Worksheet
    Dim DerLigRef As Long, DerLigMois As Long
    Application.ScreenUpdating = False
    Set ShRef = Sheets("Bilan 2011")
    Set ShMois = Sheets("Janvier")
    With ShRef
        'On cherche la derniere ligne de la liste des noms de référence
        DerLigRef = .Range("D" & .Rows.Count).End(xlUp).Row
    End With
    With ShMois
        'On cherche la derniere ligne de la liste des noms de janvier
        DerLigMois = .Range("A" & .Rows.Count).End(xlUp).Row
        For i = 1 To DerLigMois
            v = .Range("A" & i)
            'On cherche chacun des noms de janvier dans la liste de référence
            Set c = ShRef.Range("D1:D" & DerLigRef).Find(v, LookIn:=xlValues)
            'Si on ne trouve pas, on copie la plage "A:B" dans "E:F"
            If c Is Nothing Then .Range(.Cells(i, "E"), .Cells(i, "F")).Value = .Range(.Cells(i, "A"), .Cells(i, "B")).Value
        Next i
    End With
    Application.ScreenUpdating = True
End Sub

cordialement.

[dave.bonnin]

merci beaucoup.

Ca marche nickel.
Vais me pencher maintenant sur ton code pour essayer de le comprendre.

merci encore et a une prochaine.