Discussion :

[persia]

Bonjour à tous,

Étant pas très fort dans les fonctions et macros excel, j'aurais besoin de votre aide sur le sujet suivant

J'ai une page html qui contient les lignes suivantes:

Code html :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
<option value="45">Php</option>
 
<option value="10">Java</option>
 
<option value="3">C#</option>
...

Et je veux récupérer le texte qui est à l'intérieur des options,c-a-d

php,java,c#

J'ai pensé à tout simplement remplacer </option> par une chaine de caractère vide, mais le problème c'est avec les <option value=""> car c'est pas du texte statique. J'ai donc pensé à remplacer tout ce qui est à l'intérieur des <> par une chaine vide mais je ne sais pas comment faire cela dans excel.Avez-vous une idée comment je pourrais procéder ?

Merci

[kiki29]

Salut,

Si s est la chaine de caracteres,il y aura peut-être à faire un Trim sur s

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
        PosD = InStr(s, ">")
        PosF = InStr(2, s, "<")
        sStr = Mid$(s, PosD + 1, PosF - PosD - 1)

[mercatog]

Bonjour
Une fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Function ListeMots(Str As String) As String
Dim Res As String
 
Do
    Str = Mid(Str, InStr(Str, ">") + 1)
    If InStr(Str, "<") = 0 Then Exit Do
    If Mid(Str, InStr(Str, "<") + 1, 1) = "/" Then Res = Res & "," & Left(Str, InStr(Str, "<") - 1)
Loop
If Len(Res) > 1 Then ListeMots = Mid(Res, 2)
End Function

à tester comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
Dim Txt As String
 
Txt = Sheets("Feuil3").Range("A1").Value
Debug.Print ListeMots(Txt)
End Sub

[pgz]

Bonjour.

Je te propose un bout de code qui devrait te donner qq idées

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub persia()
Dim i2 As Long, i1 As Long
Const s As String = "<option value=""45"">Php</option>" & vbLf & _
                    "<option value=""10"">Java</option>" & vbLf & _
                    "<option value=""3"">C#</option>"
 
Debug.Print "Chaîne complète : " & vbCrLf & s
 
i2 = InStr(1, s, "</option>")
 
While i2 > 0
    i1 = InStrRev(s, ">", i2)
    If i1 > 0 Then
        'ici on peut lire 1 info
        Debug.Print "Option : " & Mid$(s, i1 + 1, i2 - i1 - 1)
    End If
    i2 = InStr(i2 + 1, s, "</option>")
Wend
 
End Sub

On obtient dans la fenêtre d'exécution

Chaîne complète :
<option value="45">Php</option>
<option value="10">Java</option>
<option value="3">C#</option>
Option : Php
Option : Java
Option : C#

Cordialement,

PGZ

[persia]

à tester comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
Dim Txt As String
 
Txt = Sheets("Feuil3").Range("A1").Value
Debug.Print ListeMots(Txt)
End Sub

Merci pour ta réponse, mais est-ce qu'il ya un moyen d'afficher le résutlat dans la colone B par exemple étant donné que mes données sont dans la colonne A? car je dois exporter ses données vers une table sql plus tard.
Avec le debug.print où je peux voir le résultat exactement? j'ai crée un bouton, et j'ai roulé la macro, mais la fenêtre de debug n'apparait pas, dsl mais je débute dans les macros et j'utilise Excel 2007

[mercatog]

Bonsoir
le Debug.print c'est pour voir le résultat dans la fenêtre d'exécution de l'éditeur vba.
tu peux essayer ce code sur la feuille active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
Dim Txt As String
 
Txt = Range("A1").Value
Range("B1").Value = ListeMots(Txt)
End Sub

[persia]

J'ai un résultat qui s'affiche et c'est très positif , mais juste une toute petite dernière question, comment je pourrais appliquer le résultat sur les autres cellules ? car seule la colonne B1 est affecté.

Résultats escomptés dans la colonne B:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Php
Java
C#

Merci

[mercatog]

Essaies comme ceci avec la même fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Test()
Dim Tb As Variant
 
With Sheets("Feuil2")
    Tb = Split(ListeMots(.Range("A1").Value), ",")
    .Range("B1:B" & UBound(Tb) + 1).Value = Application.Transpose(Tb)
End With
End Sub

Sinon, une autre manière:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function ListeMots2(Str As String) As Variant
Dim Res() As String
Dim i As Integer
 
Do
    Str = Mid(Str, InStr(Str, ">") + 1)
    If InStr(Str, "<") = 0 Then Exit Do
    If Mid(Str, InStr(Str, "<") + 1, 1) = "/" Then
        i = i + 1
        ReDim Preserve Res(1 To i)
        Res(i) = Left(Str, InStr(Str, "<") - 1)
    End If
Loop
ListeMots2 = Res
End Function
 
Sub Test2()
Dim Tb As Variant
 
With Sheets("Feuil1")
    Tb = ListeMots2(.Range("A1").Value)
    .Range("B1:B" & UBound(Tb)).Value = Application.Transpose(Tb)
End With
End Sub